return-to-the-roots-0.7.2.ebuild

return-to-the-roots-0.7.2.ebuild (text/plain), 1.80 KB, created by James Le Cuirot on 2011-04-15 22:10:44 UTC

# Copyright 1999-2011 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

MY_PN="s25rttr"
MY_P="${MY_PN}-${PV}"
EAPI="3"

inherit eutils games cmake-utils

DESCRIPTION="Open source rewrite of The Settlers 2, requires commercial data files"
HOMEPAGE="http://www.siedler25.org/"
SRC_URI="http://dev.gentooexperimental.org/~chewi/distfiles/${MY_P}.tar.xz"

LICENSE="GPL-3"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE=""

DEPEND="app-arch/bzip2
	media-libs/libsdl
	media-libs/sdl-mixer
	net-libs/miniupnpc
	virtual/opengl"

RDEPEND="${DEPEND}
	games-strategy/settlers2-data"

S="${WORKDIR}/${MY_P}"
CMAKE_BUILD_DIR="${S}/build"

mycmakeargs=(
	"-DBINDIR=${GAMES_BINDIR}"
	"-DDATADIR=${GAMES_DATADIR}/${MY_PN}"
	"-DGAMEDIR=${GAMES_DATADIR}/settlers2"
	"-DDRIVERDIR=$(games_get_libdir)/${MY_PN}"
	"-DCOMPILEFOR_PLATFORM=linux.local"
)

src_prepare() {
	# Fix -fPIC issues.
	epatch "${FILESDIR}/fpic.patch" || die

	# Adjust paths for Gentoo.
	epatch "${FILESDIR}/paths.patch"
	sed -i "s/RTTRDIR/DATADIR/g" libutil/src/files.h || die

	# This directory is needed to build.
	mkdir -p "${CMAKE_BUILD_DIR}/RTTR" || die

	# We don't want the update utility.
	sed -i -e "/s25update/d" -e "/ADD_CUSTOM_TARGET(updateversion\b/,/)/d" CMakeLists.txt || die

	# Don't set relative RPATHs.
	sed -i "/LINK_DIRECTORIES/d" src/CMakeLists.txt libutil/src/CMakeLists.txt || die
}

src_install() {
	dogamesbin build/src/s25client || die
	make_desktop_entry s25client "Return to the Roots" settlers2

	exeinto "$(games_get_libdir)/${MY_PN}"
	doexe build/RTTR/{s-c_resample,sound-convert} || die

	local AV; for AV in audio video; do
		exeinto "$(games_get_libdir)/${MY_PN}/${AV}"
		doexe "build/driver/${AV}/SDL/src/lib${AV}SDL.so" || die
	done

	insinto "${GAMES_DATADIR}/${MY_PN}"
	doins -r RTTR/* || die

	prepgamesdirs
}