osmos-1.6.1.ebuild

osmos-1.6.1.ebuild (text/plain), 1.24 KB, created by James Le Cuirot on 2011-04-13 22:19:05 UTC

# Copyright 1999-2011 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

EAPI=2

inherit eutils games

MY_PN="Osmos"
MY_P="${MY_PN}_${PV}"

DESCRIPTION="Play as a single-celled organism absorbing others"
HOMEPAGE="http://www.hemispheregames.com/osmos/"
SRC_URI="${MY_P}.tar.gz"

LICENSE="OSMOS"
SLOT="0"
KEYWORDS="-* ~amd64 ~x86"
IUSE=""
RESTRICT="fetch strip"
PROPERTIES="interactive"

RDEPEND="media-libs/freetype:2
	media-libs/libvorbis
	media-libs/openal
	x11-libs/libX11
	virtual/glu
	virtual/opengl"

DEPEND=""

S="${WORKDIR}/${MY_PN}"
GAMES_CHECK_LICENSE="yes"

pkg_nofetch() {
	einfo "Osmos is a commercial game. If you don't have it already, it can be"
	einfo "purchased from ${HOMEPAGE}. Please download"
	einfo "${MY_P}.tar.gz and place it into ${DISTDIR}."
}

src_install() {
	local dir="${GAMES_PREFIX_OPT}/${PN}"
	exeinto "${dir}"

	if use amd64 ; then
		newexe ${MY_PN}.bin64 ${MY_PN} || die
	elif use x86 ; then
		newexe ${MY_PN}.bin32 ${MY_PN} || die
	fi

	insinto "${dir}"
	doins -r Fonts/ Sounds/ Textures/ Osmos-*.loc *.cfg || die
	dohtml readme.html || die

	newicon Icons/256x256.png ${PN}.png || die
	games_make_wrapper ${PN} ./${MY_PN} "${dir}"
	make_desktop_entry ${PN} "Osmos"

	prepgamesdirs
}