New ebuild for xscorch-0.2.1-pre2 that applies some necessary patches for >=gtk+-2.20

xscorch-0.2.1_pre2.ebuild (text/plain), 1020 bytes, created by Brett T. Warden on 2011-04-07 18:56:32 UTC

# Copyright 1999-2009 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header$

EAPI=2
inherit eutils games versionator

DESCRIPTION="clone of the classic DOS game, 'Scorched Earth'"
HOMEPAGE="http://xscorch.org"
MY_PV=$(replace_version_separator 3 '-')
MY_P="${PN}-${MY_PV}"
SRC_URI="http://xscorch.org/releases/${MY_P}.tar.gz"
S="${WORKDIR}/${MY_P}"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~x86"
IUSE="gtk mikmod"

DEPEND="gtk? ( >=x11-libs/gtk+-2.20 )
	mikmod? ( media-libs/libmikmod )"

src_prepare() {
	epatch \
		"${FILESDIR}"/${P}-gtk-2.20-deprecated.patch \
		"${FILESDIR}"/${P}-as-needed.patch
}

src_configure() {
	#configure failed on readline support
	egamesconf \
		--enable-network \
		--without-readline \
		$(use_enable mikmod sound) \
		$(use_with gtk) \
		|| die
}

src_install() {
	make DESTDIR="${D}" install || die "make install failed"
	dodoc AUTHORS ChangeLog NEWS README TODO
	# remove unneeded, empty directory
	rmdir "${D}"/usr/games/include
	prepgamesdirs
}