Geiser ebuild (needs files/50geiser-gentoo.el)

geiser-0.1.2.ebuild (text/plain), 1.02 KB, created by Dmitry Dzhus on 2011-04-01 19:53:55 UTC

# Copyright 1999-2010 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

EAPI=2

NEED_EMACS=23

inherit autotools elisp

DESCRIPTION="Generic Emacs/Scheme interaction mode which supports Guile and Racket."
HOMEPAGE="http://www.nongnu.org/geiser/"
LICENSE="BSD"
SRC_URI="mirror://nongnu/${PN}/${PV}/${P}.tar.gz"

IUSE="guile racket"
KEYWORDS="~x86"
SLOT="0"

DEPEND=""
RDEPEND="guile? ( >=dev-scheme/guile-2.0 )
		racket? ( >=dev-scheme/racket-5.0.1 )"

SITEFILE="50${PN}-gentoo.el"

src_prepare() {
	# TODO: Do not install racket/guile files if they aren't needed

	eautoreconf || die
}

src_configure() {
	econf --with-lispdir="${SITELISP}/${PN}"
}

# We have to use geiser's build system instead of default functions
# from elisp.eclass

src_compile() {
	emake || die
}

src_install() {
	emake DESTDIR="${D}" install || die
	elisp-site-file-install "${FILESDIR}/${SITEFILE}" || die
	dodoc AUTHORS NEWS README THANKS
}

pkg_postinst() {
	elisp-site-regen
}

pkg_postrm() {
	elisp-site-regen
}