CEDET bzr ebuild

cedet-9999-r1.ebuild (text/plain), 2.23 KB, created by Dmitry Dzhus on 2011-03-29 10:55:43 UTC

# Copyright 1999-2009 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

NEED_EMACS=22

EBZR_REPO_URI="bzr://cedet.bzr.sourceforge.net/bzrroot/cedet/code/trunk"

# Inherit bzr last so that bzr_src_unpack takes action
inherit elisp eutils bzr

DESCRIPTION="CEDET: Collection of Emacs Development Tools"
HOMEPAGE="http://cedet.sourceforge.net/"

LICENSE="GPL-2 FDL-1.1"
SLOT="0"
KEYWORDS="~amd64 ~ppc ~sparc ~x86"
IUSE=""

DEPEND=""
RDEPEND="!app-emacs/semantic
	!app-emacs/eieio
	!app-emacs/speedbar"

S="${WORKDIR}/${P}"

SITEFILE="50${PN}-gentoo.el"

src_compile() {
	emake -j1 EMACS="${EMACS}" || die "emake failed"
}

#src_test() {
#	make utest || die "make utest failed"
#}

src_install() {
	local target file dir
	find . -type d \( -name tests -o -name www \) -prune -o -type f -print \
		| while read target
	do
		file=${target##*/}
		dir=${target%/*}; dir=${dir#./}
		case "${file}" in
			*~ | Makefile* | *.texi | *-script | PRERELEASE_CHECKLIST \
				| Project.ede | USING_CEDET_FROM_CVS | gettodos.sh \
				| test.dot | grammar-fw-ov.txt | grammar-fw-ov.dia)
				;;
			ChangeLog | README | AUTHORS | *NEWS | INSTALL | *.txt \
				| semanticdb.sh)
				docinto "${dir}"
				dodoc "${target}" || die ;;
			*.el | *.by | *.wy)
				# install grammar sources along with the elisp files, since
				# the location where semantic expects them is not configurable
				insinto "${SITELISP}/${PN}/${dir}"
				doins "${target}" || die ;;
			*.elc)
				# we are in a subshell, so collecting in a variable won't work
				echo "${target}" >>"${T}/elc-list.txt" ;;
			*.srt | *.xpm)
				insinto "${SITEETC}/${PN}/${dir}"
				doins "${target}" || die ;;
			*.info* | grammar-fw-ov.png)
				doinfo "${target}" || die ;;
			*)
				# don't die in the live ebuild since upstream may add files
				# die "Unrecognised file ${target}" ;;
				ewarn "Unrecognised file ${target}" ;;
		esac
	done

	# make sure that the compiled elisp files have a later time stamp than
	# the corresponding sources, in order to suppress warnings at run time
	while read target; do
		dir=${target%/*}; dir=${dir#./}
		insinto "${SITELISP}/${PN}/${dir}"
		doins "${target}" || die
	done <"${T}/elc-list.txt"

	elisp-site-file-install "${FILESDIR}/${SITEFILE}" || die
}