inherit kde
need-kde 3.1

DESCRIPTION="K3b, KDE CD Writing Software"
HOMEPAGE="http://www.k3b.org/"
SRC_URI="mirror://sourceforge/k3b/${P}.tar.bz2"

LICENSE="GPL-2"
KEYWORDS="~x86"
IUSE="debug dvdr kde oggvorbis mad flac encode"

DEPEND="${DEPEND}
	kde? ( >=kde-base/kdebase-3.1 )
	>=media-sound/cdparanoia-3.9.8
	>=media-libs/id3lib-3.8.0_pre2
	flac? ( media-libs/flac )
	mad? ( >=media-sound/mad-0.14.2b )
	oggvorbis? ( media-libs/libvorbis )"
RDEPEND="${RDEPEND}
	>=app-cdr/cdrtools-1.11
	>=app-cdr/cdrdao-1.1.7-r3
	media-sound/normalize
	dvdr? ( app-cdr/dvd+rw-tools )
	encode? ( media-sound/lame
		  media-sound/sox
		  media-video/transcode
		  media-video/vcdimager )"

LANGS="ar bg ca bs da de cs el es et fi fo fr gl hu ja it nb nl pl \
pt ro ru sk sl ta sr sv tr xh xx zu nso ven en_GB pt_BR zh_CN zh_TW"

# Documentation packages are less (in general they may contain
# other packages too,  not in this case)
LANGS_DOC="da de es et fr it pt ru sv pt_BR"

I18N="${PN}-i18n-${PV%.*}"

for pkg in ${LANGS}
do
	SRC_URI="${SRC_URI} linguas_${pkg}? ( mirror://sourceforge/k3b/${I18N}.tar.bz2 )"
done

# The package is unpacked as k3b-i18n-0.11.6, even though its name 
# is k3b.i18n-0.11.tar.bz2: we recover the final ".6"
I18N="${PN}-i18n-${PV}"
SI18N="${WORKDIR}/${I18N}"

src_compile() {
	local _S=${S}
	local myconf="--enable-libsuffix="

	use debug && myconf="${myconf} --enable-debugging --enable-profiling" \
		|| myconf="${myconf} --disable-debugging --disable-profiling"
	use kde || myconf="${myconf} --without-k3bsetup"

	# Build process of K3B
	kde_src_compile

	# Build process of K3B-i18n, select LINGUAS elements
	S=${WORKDIR}/${I18N}
	if [ -n "${LINGUAS}" -a -d "${S}" ]; then
		MAKE_PO="SUBDIRS = "
		for pkglinguas in ${LINGUAS}
		do
			for pkglangs in ${LANGS}
			do
				if [ "${pkglinguas}" = "${pkglangs}" ]; then
					MAKE_PO="${MAKE_PO} ${pkglangs}" 
				fi
			done
		done

		echo ${MAKE_PO} > ${S}/po/Makefile.am
		
		
		MAKE_DOC="SUBDIRS = " 
		for pkglinguas in ${LINGUAS}
		do
			for pkglangsdoc in ${LANGS_DOC}
			do
				if [ "${pkglinguas}" = "${pkglangsdoc}" ]; then
					MAKE_DOC="${MAKE_DOC} ${pkglangsdoc}" 
				fi
			done
		done

		echo ${MAKE_DOC} > ${S}/doc/Makefile.am
		
		ebegin "Running aclocal and automake, fixes bug #32564..."
		kde_src_compile myconf
		aclocal
		if [ "$?" -eq 0 ]; then
		    WANT_AUTOMAKE="1.7" automake
		fi
		eend $?
		myconf="${myconf} --prefix=${KDEDIR} -C"
		kde_src_compile configure
		kde_src_compile make
fi
	S=${_S}
}

src_install() {
	make DESTDIR=${D} install || die

	dodoc AUTHORS COPYING ChangeLog FAQ README TODO

	if [ -n "${LINGUAS}" -a -d "${WORKDIR}/${SI18N}" ]; then
		cd ${WORKDIR}/${I18N}
		make install DESTDIR=${D} destdir=${D} || die
	fi
}

pkg_postinst()
{
	if use kde; then
		einfo "The k3b setup program will offer to change some permissions and"
		einfo "create a user group.  These changes are not necessary.  We recommend"
		einfo "that you clear the two check boxes that let k3b make changes for"
		einfo "cdrecord and cdrdao and let k3b make changes for the devices when"
		einfo "running k3b setup."
		echo
	fi
}