Version update and other minor changes

wxformbuilder-3.1.70.ebuild (text/plain), 1.56 KB, created by Thomas J. Moore on 2011-03-06 01:51:21 UTC

# Copyright 2011 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

EAPI=2
WX_GTK_VER="2.8"

inherit eutils multilib wxwidgets

RDEPEND="x11-libs/wxGTK:2.8[X,debug?]
        dev-util/ticpp"
DEPEND="${RDEPEND}
	dev-util/premake"

DESCRIPTION="The OpenSource wxWidgets Designer, GUI Builder, and RAD Tool"
HOMEPAGE="http://wxformbuilder.org/"
SRC_URI="mirror://sourceforge/${PN}/wxFormBuilder_v${PV}-src.tar.bz2"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="debug sdk"

S=${WORKDIR}/${PN}

src_prepare() {
	# use system ticpp
	sed -i '/tinyxml/d' premake.lua
	find -name premake.lua -exec sed -i 's%../../sdk/tinyxml%/usr/include/ticpp%;s/TiCPP/ticpp/g' {} \;
}

src_configure() {
	# use system premake
	premake --target gnu --unicode `use debug || echo --disable-wx-debug` --with-wx-shared
	# use user-defined CFLAGS
	find . -name Makefile -exec sed -i "s/ -O. / ${CFLAGS} /g;s/ -s / ${LDFLAGS} /g" {} \;
}

src_compile() {
	use debug && myconfig="Debug" || myconfig="Release"
	emake CONFIG=${myconfig} CC=$(tc-getCC) CXX=$(tc-getCXX) || die "make failed"
}

src_install() {
	if use sdk; then
		insinto /usr/include/${PN}
		doins sdk/plugin_interface/*.h
		insinto /usr/$(get_libdir)/${PN}
		doins sdk/lib/*.a
		newdoc sdk/README.TXT SDK-README.TXT
	fi
	cd output
	dodoc *.txt
	dobin bin/*
	insinto /usr/$(get_libdir)
	doins -r lib/*
	insinto /usr/share/${PN}
	doins -r plugins resources xml
	cd ../install/linux/data
	doman wxformbuilder.1
	doicon `find gnome -name \*.png -print`
	make_desktop_entry /usr/bin/wxformbuilder wxFormBuilder
}