Ebuild for nagvis 1.5.8

nagvis-1.5.8.ebuild (text/plain), 2.47 KB, created by Thomas Oettli on 2011-03-04 10:30:22 UTC

# Copyright 1999-2009 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

EAPI=2

inherit eutils confutils depend.php depend.apache

DESCRIPTION="NagVis is a visualization addon for the well known network managment system Nagios."
HOMEPAGE="http://www.nagvis.org/"
SRC_URI="mirror://sourceforge/${PN}/${P}.tar.gz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~ppc ~x86"
IUSE="apache2 automap"

DEPEND=""
RDEPEND="|| ( net-analyzer/nagios net-analyzer/icinga )
		automap? ( >=media-gfx/graphviz-2.14 )
		apache2? ( dev-lang/php[apache2] )
		dev-lang/php[gd,mysql,session,sockets,sqlite3,unicode,xml]"

need_php_httpd
want_apache2

pkg_setup() {
	confutils_require_built_with_all dev-lang/php gd mysql session sockets sqlite3 unicode xml
	depend.apache_pkg_setup
}

src_prepare() {
	pwd
	epatch "${FILESDIR}"/${P}-base-path.patch
	epatch "${FILESDIR}"/${P}-global-defines.patch
	grep -Rl "/usr/local" "${S}"/* | xargs sed -i s:/usr/local:/usr:g
	sed -i s:@NAGVIS_WEB@:/nagvis:g "${S}"/etc/apache2-nagvis.conf-sample
	sed -i s:@NAGVIS_PATH@/share:/usr/share/nagvis/:g "${S}"/etc/apache2-nagvis.conf-sample
}

src_install() {
	for docfile in README INSTALL
	do
		dodoc ${docfile}
		rm ${docfile}
	done

	dodir /usr/share/nagvis
	mv "${S}"/share/{config.php,index.php,frontend,netmap,server,userfiles} "${D}"/usr/share/nagvis/

	dodir /var/nagvis
	dodir /var/nagvis/tmpl
	dodir /var/nagvis/tmpl/{cache,compile}
	fowners apache:root /var/nagvis
	fowners apache:root /var/nagvis/tmpl
	fowners apache:root /var/nagvis/tmpl/{cache,compile}
	dosym /var/nagvis /usr/share/nagvis/var

	if use apache2 ; then
		insinto "${APACHE_MODULES_CONFDIR}"
		newins "${S}"/etc/apache2-nagvis.conf-sample 98_${PN}.conf
	fi
	rm "${S}"/etc/apache2-nagvis.conf-sample

	dodir /etc/nagvis
	mv "${S}"/etc/* "${D}"/etc/nagvis/
	dosym /etc/nagvis /usr/share/nagvis/etc

	fperms 664 /etc/nagvis/nagvis.ini.php-sample
	fperms 775 /etc/nagvis/maps
	fowners apache:root /etc/nagvis/maps

	chmod 664 "${D}"/etc/nagvis/maps/*cfg
	chown apache:root "${D}"/etc/nagvis/maps/*cfg
}

pkg_postinst() {
	elog "Before running NagVis for the first time, you will need to set up"
	elog "/etc/nagvis/nagvis.ini.php"
	elog "A sample is in"
	elog "/etc/nagvis/nagvis.ini.php-sample"
	if use apache2 ; then
		elog
		elog "For web interface make sure to add -D NAGVIS to APACHE2_OPTS in"
		elog "/etc/conf.d/apache2 and to restart apache2. A default configuration"
		elog "has been placed at /etc/apache2/modules.d/98_${PN}.conf"
	fi
}