Ecopied and prefexified ebuild

mongodb-1.6.0.ebuild (text/plain), 2.31 KB, created by Sven Schwyn (svoop) on 2011-02-15 12:00:15 UTC

# Copyright 1999-2011 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-db/mongodb/mongodb-1.6.0.ebuild,v 1.2 2011/02/02 18:14:42 phajdan.jr Exp $

EAPI="2"

inherit eutils versionator

MY_PATCHVER=$(get_version_component_range 1-2)
MY_P="${PN}-src-r${PV}"

DESCRIPTION="A high-performance, open source, schema-free document-oriented database"
HOMEPAGE="http://www.mongodb.org"
SRC_URI="http://downloads.mongodb.org/src/${MY_P}.tar.gz"

LICENSE="AGPL-3"
SLOT="0"
KEYWORDS="~x86-macos"
IUSE="v8"

RDEPEND="!v8? ( dev-lang/spidermonkey[unicode] )
	v8? ( dev-lang/v8 )
	dev-libs/boost
	dev-libs/libpcre"

DEPEND="${RDEPEND}
	>=dev-util/scons-1.2.0-r1
	sys-libs/readline
	sys-libs/ncurses"

# Must change this on every upgrade
S="${WORKDIR}/${MY_P}"

pkg_setup() {
	enewgroup mongodb
	enewuser mongodb -1 -1 /var/lib/${PN} mongodb

	scons_opts="${MAKEOPTS}"

	# Use target arch detection logic from bug #296917.
	local myarch="$ABI"
	[[ $myarch = "" ]] && myarch="$ARCH"

	if [[ $myarch =~ 64 ]] ; then
		scons_opts+=" --64"
	elif [[ $myarch =~ 32 ]] ; then
		scons_opts+=" --32"
	elif [[ $myarch =~ x86 ]] ; then
		scons_opts+=" --32"
	else
		die "Failed to determine target arch, got '$myarch'."
	fi
	
	# Pass paths for Gentoo Prefix
	scons_opts+=" --cpppath ${EPREFIX}/usr/include --libpath ${EPREFIX}/usr/lib"

	if use v8; then
		scons_opts+=" --usev8"
	else
		scons_opts+=" --usesm"
	fi
}

src_prepare() {
	epatch "${FILESDIR}/${P}-fix-scons.patch"
#}	epatch "${FILESDIR}"/"${PN}"-"${MY_PATCHVER}"-modify-*.patch

	if use v8; then
		# Suppress known test failure with v8:
		# http://jira.mongodb.org/browse/SERVER-1147
		sed -e '/add< NumberLong >/d' -i dbtests/jstests.cpp || die
	fi
}

src_compile() {
	scons ${scons_opts} all || die "Compile failed"
}

src_install() {
	scons ${scons_opts} --full --nostrip install --prefix="${ED}"/usr || die "Install failed"

	for x in /var/{lib,log,run}/${PN}; do
		dodir "${x}" || die "Install failed"
		fowners mongodb:mongodb "${x}"
	done

	doman debian/mongo*.1 || die "Install failed"
	dodoc README docs/building.md

	newinitd "${FILESDIR}/${PN}.initd" ${PN} || die "Install failed"
	newconfd "${FILESDIR}/${PN}.confd" ${PN} || die "Install failed"
}

src_test() {
	scons ${scons_opts} smoke --smokedbprefix='testdir' test || die "Tests failed"
}