# Copyright 1999-2010 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/x11-misc/synergy/synergy-1.3.1-r2.ebuild,v 1.2 2010/07/19 18:49:43 darkside Exp $

EAPI="3"
inherit cmake-utils

DESCRIPTION="Lets you easily share a single mouse and keyboard between multiple computers."
SRC_URI="http://synergy.googlecode.com/files/${P}-Source.tar.gz"

HOMEPAGE="http://synergy-foss.org/"
LICENSE="GPL-2"
KEYWORDS="~alpha ~amd64 ~arm ~ppc ~ppc64 ~sparc ~x86 ~x86-fbsd ~x86-freebsd ~amd64-linux ~x86-linux ~x86-macos ~sparc-solaris ~x86-solaris"
SLOT="0"
IUSE="debug"

RDEPEND="x11-libs/libXtst
	x11-libs/libX11
	x11-libs/libXext
	x11-libs/libXinerama"
DEPEND="${RDEPEND}
	x11-proto/xextproto
	x11-proto/xproto
	x11-proto/kbproto
	x11-proto/xineramaproto
	x11-libs/libXt
	dev-util/cmake"

S=${WORKDIR}/${P}-Source

src_configure() {
	use debug && CMAKE_BUILD_TYPE=Debug
	cmake-utils_src_configure || die
}

src_install () {
	exeinto /usr/bin
	doexe ${WORKDIR}/${P}_build/synergyc ${WORKDIR}/${P}_build/synergys
	dolib ${WORKDIR}/${P}_build/libsynergy.a
	mv doc/synergyc.man doc/synergyc.1
	mv doc/synergys.man doc/synergys.1
	doman doc/synergyc.1 doc/synergys.1
	dodoc ChangeLog README doc/*.conf
	insinto /etc
	doins "${S}"/examples/synergy.conf
}

pkg_postinst() {
	elog
	elog "${PN} can also be used to connect to computers running Windows."
	elog "Visit ${HOMEPAGE} to find the Windows client."
	elog
}