# Copyright 1999-2011 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/media-libs/libbluray/libbluray-9999.ebuild,v 1.1 2010/07/17 02:55:14 beandog Exp $

EAPI=2

inherit autotools java-pkg-opt-2 git

EGIT_REPO_URI="git://git.videolan.org/libbluray.git"

DESCRIPTION="Blu-ray playback libraries"
HOMEPAGE="http://www.videolan.org/developers/${PN}.html"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS=""
IUSE="aacs java static-libs utils xine"

DEPEND="java? ( virtual/jdk:1.6 )
	xine? ( media-libs/xine-lib )
	dev-libs/libxml2"
RDEPEND="${DEPEND}
	aacs? ( media-video/aacskeys
		media-libs/libaacs )
"

src_prepare() {
	use java && export JDK_HOME="$(java-config -g JAVA_HOME)"
	eautoreconf
}

src_configure() {
	local myconf=""
	use java && myconf="--with-jdk=${JDK_HOME}"

	econf \
		$(use_enable static-libs static) \
		$(use_enable utils static) \
		$(use_enable utils examples) \
		$(use_enable java bdjava ) \
		$myconf
}

src_compile() {
	emake || die

	if use xine; then
		cd "${S}"/player_wrappers/xine
		emake || die
		cd "${S}"
	fi
}

src_install() {
	emake DESTDIR="${D}" install || die

	dodoc doc/README README.txt TODO.txt || die

	if use utils; then
		cd src/examples/
		dobin clpi_dump index_dump mobj_dump mpls_dump sound_dump || die
		cd .libs/
		dobin bd_info bdsplice hdmv_test libbluray_test list_titles || die
		use java && dobin bdj_test || die
	fi

	if use java; then
		java-pkg_dojar "${S}/src/.libs/${PN}.jar"
		newenvd "${FILESDIR}/envd" "90${PN}"
	fi

	if use xine; then
		cd "${S}"/player_wrappers/xine
		emake DESTDIR="${D}" install || die
		newdoc HOWTO README.xine
	fi
}