uodated ebuild with pmount USE & dependency

udisks-glue-1.2.0.ebuild (text/plain), 1.38 KB, created by Lucian Muresan on 2011-01-15 02:05:02 UTC

# Copyright 1999-2011 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/sys-fs/udisks-glue/udisks-glue-1.2.0.ebuild,v 1.2 2011/01/03 18:24:50 ssuominen Exp $

EAPI=2
inherit autotools

DESCRIPTION="A tool to associate udisks events to user-defined actions"
HOMEPAGE="http://github.com/fernandotcl/udisks-glue"
SRC_URI="https://github.com/fernandotcl/udisks-glue/tarball/release-1.2.0 -> ${P}.tar.gz"

LICENSE="BSD"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="+pmount"

COMMON_DEPEND="dev-libs/dbus-glib
	dev-libs/glib:2
	dev-libs/confuse"
RDEPEND="${COMMON_DEPEND}
	sys-fs/udisks
	pmount? ( sys-apps/pmount )"
DEPEND="${COMMON_DEPEND}
	dev-util/pkgconfig"

src_unpack() {
	unpack ${A}
	mv *-${PN}-* "${S}"
}

src_prepare() {
	eautoreconf
}

src_install() {
	emake DESTDIR="${D}" install || die
	dodoc ChangeLog README
	doinitd "${FILESDIR}/${PN}"
	insinto /etc
	doins "${FILESDIR}/${PN}.conf"
}

pkg_postinst() {
	einfo ""
	einfo "You may add the '${PN}' service to the default runlevel"
	einfo "if you need automount functionality in the console or your"
	einfo "window manager or utilities does/do not provide it."
	einfo ""
	einfo "You may also customize 'etc/${PN}.conf' according to the"
	einfo "comments and report back to http://bugs.gentoo.org or"
	einfo "upstream acording to the README file if you found something useful."
	einfo ""
}