fltk-1.3.0_rc3 ebuild

fltk-1.3.0_rc3.ebuild (text/plain), 3.52 KB, created by yury fedorchenko on 2011-01-10 20:52:52 UTC

# Copyright 1999-2010 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# !this is not oficial ebuild!

EAPI=2
inherit eutils autotools versionator fdo-mime

MY_P=${P/_rc3/rc3}
DESCRIPTION="C++ user interface toolkit for X and OpenGL."
HOMEPAGE="http://www.fltk.org"
SRC_URI="mirror://easysw/fltk/1.3.0rc3/${MY_P}-source.tar.gz"

KEYWORDS="amd64 x86"
LICENSE="FLTK LGPL-2"

SLOT="1.1" # because 1.3 is API compatible with 1.1

IUSE="cairo doc debug examples games opengl pdf threads xft xinerama"

RESTRICT="strip"

RDEPEND="x11-libs/libXext
	x11-libs/libICE
	x11-libs/libSM
	x11-libs/libXt
	media-libs/jpeg
	media-libs/libpng
	sys-libs/zlib
	opengl? ( virtual/opengl virtual/glu )
	xinerama? ( x11-libs/libXinerama )
	xft? ( x11-libs/libXft )"

DEPEND="${RDEPEND}
	x11-proto/xextproto
	doc? ( app-doc/doxygen )
	pdf? ( app-doc/doxygen dev-texlive/texlive-latex )
	xinerama? ( x11-proto/xineramaproto )"

INCDIR=/usr/include/fltk-${SLOT}
LIBDIR=/usr/$(get_libdir)/fltk-${SLOT}

S="${WORKDIR}/${MY_P}"

src_prepare() {
	#epatch "${FILESDIR}"/pdfinstall.diff
	# remove forced flags from fltk-config
	sed -i \
		-e '/C\(XX\)\?FLAGS=/s:@C\(XX\)\?FLAGS@::' \
		-e '/^LDFLAGS=/d' \
		"${S}/fltk-config.in" || die
	# some fixes introduced because slotting
	sed -i \
		-e '/RANLIB/s:$(libdir)/\(.*LIBNAME)\):$(libdir)/`basename \1`:g' \
		src/Makefile || die
	# docs in proper docdir
	sed -i \
		-e "/^docdir/s:fltk:${PF}/html:" \
		makeinclude.in || die
	eautoconf
}

src_configure() {
	econf \
		--includedir=${INCDIR}\
		--libdir=${LIBDIR} \
		--docdir=/usr/share/doc/${PF}/html \
		--enable-largefile \
		--enable-shared \
		--enable-xdbe \
		$(use_enable debug) \
		$(use_enable cairo) \
		$(use_enable opengl gl) \
		$(use_enable threads) \
		$(use_enable xft) \
		$(use_enable xinerama)
}

src_compile() {
	emake || die "emake failed"
	if use doc; then
		cd "${S}"/documentation
		emake html || die "emake doc failed"
		if use pdf; then
			emake pdf || die "emake doc failed"
		fi
	fi
	if use games; then
		cd "${S}"/test
		emake blocks checkers sudoku || die "emake games failed"
	fi
}

src_install() {
	emake DESTDIR="${D}" install || die "emake install failed"
	emake -C fluid \
			DESTDIR="${D}" install-linux || die "emake install fluid failed"
	if use doc; then
		emake -C documentation \
			DESTDIR="${D}" install || die "emake install doc failed"
	fi
	local apps="fluid"
	if use games; then
		emake -C test \
			DESTDIR="${D}" install-linux || die "emake install games failed"
		emake -C documentation \
			DESTDIR="${D}" install-linux || die "emake install doc games failed"
		apps="${apps} sudoku blocks checkers"
	fi
	for app in ${apps}; do
		dosym /usr/share/icons/hicolor/32x32/apps/${app}.png \
			/usr/share/pixmaps/${app}.png
	done
	dodoc CHANGES README CREDITS ANNOUNCEMENT

	if use examples; then
		insinto /usr/share/doc/${PF}/examples
		doins test/*.{h,cxx,fl} test/demo.menu
	fi

#	insinto /usr/share/cmake/Modules
#	doins CMake/FLTK*.cmake

	echo "LDPATH=${LIBDIR}" > 99fltk-${SLOT}
	echo "FLTK_DOCDIR=/usr/share/doc/${PF}/html" >> 99fltk-${SLOT}
	doenvd 99fltk-${SLOT}
}

pkg_postinst() {
	fdo-mime_desktop_database_update
	echo
	ewarn "PLEASE PLEASE take note of this"
	ewarn "Please make *sure* to run revdep-rebuild now"
	ewarn "You must recompile everithing that depend on fltk"
	ewarn ""
	ewarn "This is development version of fltk"
	ewarn "please report any bug to http://www.fltk.org"
	ewarn "or to y_fedor (at) ciam (dot) ru until fltk-1.3 is not in portage tree"
	echo 
	epause 10
	ebeep
}

pkg_postrm() {
	fdo-mime_desktop_database_update
}