Ebuild based on git & fe other enhancements

xbmc-9999.ebuild (text/plain), 6.21 KB, created by Lucian Muresan on 2011-01-05 23:57:47 UTC

# Copyright 1999-2011 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: Exp $

EAPI="2"

inherit eutils python git

if [[ ${PV} == "9999" ]] ; then
	# Define the environment variable XBMC_EGIT_REPO_URI to track a different repository
	EGIT_REPO_URI=${XBMC_EGIT_REPO_URI:-git://github.com/xbmc/xbmc.git}
	# Define the environment variable XBMC_EGIT_BRANCH to track a different branch
	if [[ -n ${XBMC_EGIT_BRANCH} ]] ; then
		EGIT_BRANCH=${XBMC_EGIT_BRANCH}
	fi
	# Define the environment variable XBMC_EGIT_PROJECT if you're tracking a different repository
	# than the official one and would like to store locally in a different folder for easily being
	# able to switch back
	EGIT_PROJECT=${XBMC_EGIT_PROJECT:-xbmc}
	# Define the environment variable XBMC_EGIT_COMMIT to override to a specific GIT commit
	if [[ -n ${XBMC_EGIT_COMMIT} ]] ; then
		EGIT_COMMIT=${XBMC_EGIT_COMMIT}
	fi

	KEYWORDS=""
else
	SRC_URI="http://mirrors.xbmc.org/releases/source/${P}.tar.gz"
	KEYWORDS="~amd64 ~x86"
fi

inherit autotools

DESCRIPTION="XBMC is a free and open source media-player and entertainment hub"
HOMEPAGE="http://xbmc.org/"

LICENSE="GPL-2"
SLOT="0"
IUSE="aac alsa altivec avahi bluray css debug ffmpeg joystick midi profile pulseaudio rtmp python sse sse2 udev vaapi vdpau webserver xrandr"

COMMON_DEPEND="virtual/opengl
	app-arch/bzip2
	app-arch/unrar
	app-arch/unzip
	app-arch/zip
	app-i18n/enca
	python? ( >=dev-lang/python-2.4 )
	dev-libs/boost
	dev-libs/fribidi
	dev-libs/libcdio[-minimal]
	dev-libs/libpcre[cxx]
	dev-libs/lzo
	>=dev-python/pysqlite-2
	media-libs/a52dec
	media-libs/alsa-lib
	aac? ( media-libs/faac )
	media-libs/faad2
	media-libs/flac
	media-libs/fontconfig
	media-libs/freetype
	media-libs/glew
	media-libs/jasper
	media-libs/jbigkit
	media-libs/jpeg:0
	>=media-libs/libass-0.9.7
	media-libs/libdca
	bluray? ( media-libs/libbluray )
	css? ( media-libs/libdvdcss )
	media-libs/libmad
	media-libs/libmms
	media-libs/libmodplug
	media-libs/libmpeg2
	media-libs/libogg
	media-libs/libsamplerate
	media-libs/libsdl[alsa=,audio,opengl,video,X]
	media-libs/libvorbis
	media-libs/sdl-gfx
	media-libs/sdl-image[gif,jpeg,png]
	media-libs/sdl-mixer
	media-libs/sdl-sound
	media-libs/tiff
	pulseaudio? ( media-sound/pulseaudio )
	media-sound/wavpack
	ffmpeg? ( >=media-video/ffmpeg-0.6 )
	rtmp? ( media-video/rtmpdump )
	avahi? ( net-dns/avahi )
	webserver? ( net-libs/libmicrohttpd )
	net-misc/curl
	|| ( >=net-fs/samba-3.4.6[smbclient] <net-fs/samba-3.3 )
	sys-apps/dbus
	sys-libs/zlib
	virtual/mysql
	x11-apps/xdpyinfo
	x11-apps/mesa-progs
	vaapi? ( x11-libs/libva )
	vdpau? (
		|| ( x11-libs/libvdpau >=x11-drivers/nvidia-drivers-180.51 )
		ffmpeg? ( media-video/ffmpeg[vdpau] )
	)
	x11-libs/libXinerama
	xrandr? ( x11-libs/libXrandr )
	x11-libs/libXrender"
# The cpluff bundled addon uses gettext which needs CVS ...
RDEPEND="${COMMON_DEPEND}
	udev? ( sys-fs/udisks sys-power/upower )"
DEPEND="${COMMON_DEPEND}
	dev-util/gperf
	dev-vcs/cvs
	x11-proto/xineramaproto
	dev-util/cmake
	x86? ( dev-lang/nasm )"

src_unpack() {
	if [[ ${PV} == "9999" ]] ; then
		# if we did not request an explicit commit in the environment variable, but a specific branch, get the commit of the requested branch:
		if [[ -z "${XBMC_EGIT_COMMIT}" && -n "${XBMC_EGIT_BRANCH}" ]]; then
			cd "${EGIT_STORE_DIR}/${PN}"
			EGIT_COMMIT="$(git ls-remote --heads origin | grep ${EGIT_BRANCH} | cut -b 1-40)"
		fi
		git_src_unpack
		cd "${S}"
		rm -f configure
	else
		unpack ${A}
		cd "${S}"
	fi

	# Fix case sensitivity
	mv media/Fonts/{a,A}rial.ttf || die
	mv media/{S,s}plash.png || die
}

src_prepare() {
	# some dirs ship generated autotools, some dont
	local d
	for d in . xbmc/cores/dvdplayer/Codecs/{libdts,libdvd/lib*/} lib/cpluff ; do
		[[ -e ${d}/configure ]] && continue
		pushd ${d} >/dev/null
		einfo "Generating autotools in ${d}"
		eautoreconf
		popd >/dev/null
	done

	local squish #290564
	use altivec && squish="-DSQUISH_USE_ALTIVEC=1 -maltivec"
	use sse && squish="-DSQUISH_USE_SSE=1 -msse"
	use sse2 && squish="-DSQUISH_USE_SSE=2 -msse2"
	sed -i \
		-e '/^CXXFLAGS/{s:-D[^=]*=.::;s:-m[[:alnum:]]*::}' \
		-e "1iCXXFLAGS += ${squish}" \
		xbmc/lib/libsquish/Makefile.in || die

	# Fix XBMC's final version string showing as "exported"
	# instead of the SVN revision number.
#	export SVN_REV=${ESVN_WC_REVISION:-exported}

	# Avoid lsb-release dependency
	sed -i \
		-e 's:lsb_release -d:cat /etc/gentoo-release:' \
		xbmc/utils/SystemInfo.cpp

	# Do not use termcap #262822
	sed -i 's:-ltermcap::' xbmc/lib/libPython/Python/configure

	# avoid long delays when powerkit isn't running #348580
	sed -i \
		-e '/dbus_connection_send_with_reply_and_block/s:-1:3000:' \
		xbmc/linux/*.cpp || die

	# Tweak autotool timestamps to avoid regeneration
	find . -type f -print0 | xargs -0 touch -r configure
}

src_configure() {
	# Disable documentation generation
	export ac_cv_path_LATEX=no
	# Avoid help2man
	export HELP2MAN=$(type -P help2man || echo true)

	econf \
		--docdir=/usr/share/doc/${PF} \
		--disable-ccache \
		--disable-optimizations \
		--enable-external-liba52 \
		--enable-external-libdts \
		$(use_enable python external-python) \
		$(use_enable ffmpeg external-ffmpeg) \
		--enable-goom \
		--enable-gl \
		$(use_enable avahi) \
		$(use_enable css dvdcss) \
		$(use_enable debug) \
		$(use_enable aac faac) \
		--disable-hal \
		$(use_enable joystick) \
		$(use_enable midi mid) \
		$(use_enable profile profiling) \
		$(use_enable pulseaudio pulse) \
		$(use_enable rtmp) \
		$(use_enable vaapi) \
		$(use_enable vdpau) \
		$(use_enable webserver) \
		$(use_enable bluray libbluray) \
		$(use_enable xrandr)
}

src_install() {
	emake install DESTDIR="${D}" || die
	dodoc keymapping.txt README.linux
	rm "${D}"/usr/share/doc/${PF}/{copying.txt,LICENSE.GPL} || die

#	insinto /usr/share/applications
#	doins tools/Linux/xbmc.desktop
#	doicon tools/Linux/xbmc.png

	insinto "$(python_get_sitedir)" #309885
	doins tools/EventClients/lib/python/xbmcclient.py || die
	newbin "tools/EventClients/Clients/XBMC Send/xbmc-send.py" xbmc-send || die
	if ! [[ "${ARCH}" =~ "-macos" ]]; then
		einfo "removing /usr/share/xbmc/system/libcurl-*-osx.so from installation"
		rm "${D}"/usr/share/xbmc/system/libcurl-*-osx.so
	fi
}

pkg_postinst() {
	elog "Visit http://wiki.xbmc.org/?title=XBMC_Online_Manual"
}