Stable release of osc

osc-0.127.ebuild (text/plain), 1.28 KB, created by Michal Hrusecky (RETIRED) on 2011-01-04 22:08:58 UTC

# Copyright 1999-2010 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

EAPI=3

EGIT_REPO_URI="git://gitorious.org/opensuse/osc.git"

[[ "${PV}" == "9999" ]] && EXTRA_ECLASS="git"

inherit distutils ${EXTRA_ECLASS}

DESCRIPTION="The openSUSE build service command line tool."
HOMEPAGE="http://en.opensuse.org/openSUSE:OSC"

[[ "${PV}" == "9999" ]] || SRC_URI="https://api.opensuse.org/public/source/openSUSE:11.3/${PN}/${P}.tar.gz"

LICENSE="GPL-2"
SLOT="0"
IUSE=""

if [[ "${PV}" == "9999" ]]; then
	KEYWORDS=""
else
	KEYWORDS="~amd64 ~x86"
fi

DEPEND="dev-python/urlgrabber
	dev-python/pyxml
	dev-python/m2crypto"
RDEPEND="${DEPEND}
	dev-util/suse-build"

DOCS="README NEWS AUTHORS TODO"

src_install() {
	distutils_src_install
	dosym osc-wrapper.py /usr/bin/osc || \
		die "Creating /usr/bin/osc failed"
	keepdir /usr/lib/osc/source_validators    || \
		die "Creating /usr/lib/osc/source_validators failed"
	cd "${D}"/usr/
	find . -exec grep -l /usr/bin/build \{\} \; | while read i; do
		sed -i 's|/usr/bin/build|/usr/bin/suse-build|'   "${i}" \
			|| die "sed for /usr/${i} failed"
	done
	find . -exec grep -l /usr/lib/build \{\} \; | while read i; do
		sed -i 's|/usr/lib/build|/usr/share/suse-build|' "${i}" \
			|| die "sed for /usr/${i} failed"
	done
}