Current snapshot os build (osc dependency)

suse-build-9999.ebuild (text/plain), 1.26 KB, created by Michal Hrusecky (RETIRED) on 2011-01-04 22:08:28 UTC

# Copyright 1999-2010 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

EAPI=3

EGIT_REPO_URI="git://gitorious.org/opensuse/build.git"

[[ "${PV}" == "9999" ]] && EXTRA_ECLASS="git"

inherit eutils ${EXTRA_ECLASS}

DESCRIPTION="A Script to build SUSE Linux RPMs"
HOMEPAGE=""

MY_PN="build"
[[ "${PV}" == "9999" ]] || SRC_URI="https://api.opensuse.org/public/source/openSUSE:11.3/${MY_PN}/${MY_PN}-${PV}.tar.gz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS=""
IUSE=""

if [[ "${PV}" == "9999" ]]; then
	KEYWORDS=""
else
	KEYWORDS="~amd64 ~x86"
fi

RDEPEND="virtual/perl-Digest-MD5
	virtual/perl-Getopt-Long
	dev-perl/XML-Parser
	dev-perl/TimeDate
	app-shells/bash
	app-arch/rpm"

S="${WORKDIR}/${MY_PN}-${PV}"

src_compile() { :; }

src_install() {
	emake DESTDIR="${D}" pkglibdir=/usr/share/suse-build install || die "make install failed"
	cd "${D}"/usr
	find bin -type l | while read i; do
		mv "${i}" "${i/bin\//bin/suse-}" || die "mv /usr/${i} failed"
	done
	find share/man/man1 -type f | while read i; do
		mv "${i}" "${i/man1\//man1/suse-}" || die "mv /usr/${i} failed"
	done
	find . -type f -exec grep -l "/usr/lib/build" \{\} \; | while read i; do
		sed -i 's|/usr/lib/build|/usr/share/suse-build|' "${i}" || die "sed /usr/${i} failed"
	done
}