# Copyright 1999-2010 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

EAPI="3"

ETYPE="sources"
K_WANT_GENPATCHES=""
K_PREDEBLOBBED="true"
PYTHON_DEPEND="2"

inherit kernel-2 python
detect_version
detect_arch

DEBIAN_REVISION="29"

SOURCE_PATCH="linux-2.6_${PV}-${DEBIAN_REVISION}.diff.gz"

DESCRIPTION="Kernel sources along with configuration files from Debian"
HOMEPAGE="http://www.debian.org/"
SRC_URI="${KERNEL_URI}
	mirror://debian/pool/main/l/linux-2.6/${SOURCE_PATCH}"

UNIPATCH_LIST="${DISTDIR}/${SOURCE_PATCH}"

LICENSE="GPL-2"
IUSE=""
KEYWORDS="~amd64 ~x86"

RDEPEND="${RDEPEND}"
DEPEND="${DEPEND}
	dev-util/unifdef"

K_NOSETEXTRAVERSION="true"
K_EXTRAELOG="Configuration files have been installed to /usr/share/doc/${PF}/"
K_SECURITY_UNSUPPORTED="1"

src_prepare() {
	DEBIAN_DIR="${S}/debian"

	mv "linux-2.6-${PV}/debian" .

	einfo "Applying orig-0 patchset"
	export PYTHONPATH="${DEBIAN_DIR}/lib/python/"
	cat > "${DEBIAN_DIR}/bin/apply-orig" <<EOF
from debian_linux.patches import PatchSeriesList
PatchSeriesList.read("${DEBIAN_DIR}/patches", ["orig-0"])()
EOF
	$(PYTHON) "${DEBIAN_DIR}/bin/apply-orig" || die

	einfo "Applying patch series"
	$(PYTHON) \
		"${DEBIAN_DIR}/bin/patch.apply" \
		-H "${DEBIAN_DIR}/patches" "${DEBIAN_REVISION}" || die

	mkdir "${DEBIAN_DIR}/build" || die
	local config_targets="build_amd64 build_i386_none_486 build_i386_none_686 \
		build_i386_none_686-bigmem"
	for cfg_target in ${config_targets}; do
		einfo "Generating configuration file: ${cfg_target}"
		commands="$(make -B -n -f debian/rules.gen ${cfg_target} 2>&1 \
			| grep ^python | sed -e "s,python ,,; s,',,g;")"
		$(PYTHON) ${commands}
	done

	einfo "Cleaning up source tree"
	rm -rf "linux-2.6-${PV}" version.Debian debian
	cp "${DEBIAN_DIR}"/build/config.* "${T}/"

	sed -i -e "s:^\(EXTRAVERSION =\).*:\1 -debian-${DEBIAN_REVISION}:" \
		Makefile
}

src_install() {
	kernel-2_src_install

	dodoc "${T}"/config.*
}