sci-geosciences/merkaartor-9999 ebuild

merkaartor-9999.ebuild (text/plain), 1.42 KB, created by Petr Morávek on 2010-12-27 18:00:21 UTC

# Copyright 1999-2009 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

EAPI="2"

inherit eutils qt4 git

EGIT_BRANCH="master"
EGIT_REPO_URI="git://gitorious.org/merkaartor/main.git"

DESCRIPTION="A Qt4 based map editor for the openstreetmap.org project"
HOMEPAGE="http://merkaartor.be/"
SRC_URI=""
LICENSE="GPL-2"
SLOT="0"
KEYWORDS=""
IUSE="nls webkit exif gps proxy"
DEPEND=">=sci-libs/proj-4.7
	>=sci-libs/gdal-1.6.0
	x11-libs/qt-gui:4
	|| ( >=x11-libs/qt-gui-4.7 >=dev-libs/boost-1.38 )
	x11-libs/qt-svg:4
	webkit? ( >=x11-libs/qt-webkit-4.3.3 )
	exif? ( media-gfx/exiv2 )
	proxy? ( net-libs/libproxy )
	gps?  ( >=sci-geosciences/gpsd-2.92 )"
RDEPEND="${DEPEND}"

S="${WORKDIR}/${PN}"

src_compile() {
	local myconf
	use webkit || myconf="${myconf} NOUSEWEBKIT=1"
	use exif && myconf="${myconf} GEOIMAGE=1" || myconf="${myconf} GEOIMAGE=0"
	use proxy && myconf="${myconf} LIBPROXY=1" || myconf="${myconf} LIBPROXY=0"
	use gps && myconf="${myconf} GPSDLIB=1" || myconf="${myconf} GPSDLIB=0"

	if use nls; then
		lrelease src/src.pro || die "lrelease failed"
	fi

	eqmake4 Merkaartor.pro LIBDIR=/usr/$(get_libdir) PREFIX=/usr ${myconf} || die "eqmake4 failed"
	emake || die "make failed"
}

src_install() {
	emake INSTALL_ROOT="${D}" install || die "install failed"
	dodoc AUTHORS CHANGELOG HACKING || die "dodoc failed"

	newicon Icons/Merkaartor_100x100.png "${PN}".png || die "newicon failed"
}