A first pass of an ebuild

beaverdbg-1.0.0_beta3.ebuild (text/plain), 1.99 KB, created by Philippe Chaintreuil on 2010-12-09 17:27:51 UTC

# Copyright 1999-2010 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-util/qt-creator/qt-creator-2.0.1.ebuild,v 1.6 2010/11/15 21:35:18 hwoarang Exp $

EAPI="2"

inherit qt4-r2
MY_PV="${PV/_beta/.b}"
MY_P="${PN}-${MY_PV}"

DESCRIPTION="Lightweight C++, C, & QScript Debugger based on QTCreator"
HOMEPAGE="http://beaverdbg.googlecode.com/"
SRC_URI="http://beaverdbg.googlecode.com/files/${MY_P}.tar.gz"

LICENSE="LGPL-2.1"
SLOT="0"
KEYWORDS="~amd64 ~ppc ~ppc64 ~x86"
IUSE=""

QTVER="4.5.0:4"
# See note below in src_prepare about qt-webkit dependancy.
DEPEND=">=x11-libs/qt-assistant-${QTVER}
	>=x11-libs/qt-core-${QTVER}
	>=x11-libs/qt-svg-${QTVER}
	>=x11-libs/qt-sql-${QTVER}
	>=x11-libs/qt-gui-${QTVER}
	>=x11-libs/qt-webkit-${QTVER}"
RDEPEND="${DEPEND}"

# Beta 3 untar's into .b2.
#S="${WORKDIR}"/"${MY_P}"
S="${WORKDIR}"/"${MY_P/.b3/.b2}"

src_prepare() {
	qt4-r2_src_prepare

	# I get a *linker* error about QWebView symbols not being found if
	# I don't make this depend on webkit.  The following sed code just
	# adds in webkit.  I'm not sure if this is because my qt-core
	# has already linked against webkit or if this is always around.
	einfo "Fixing app.pro to also depend on webkit to avoid linking errors"
	sed -i 's/^\(QT \*= core\) \(gui script svg.*\)/\1 webkit \2/' \
		"${S}/src/app/app.pro" \
		|| die "Unable to add webkit as dependancy"
}

src_configure() {
	pushd "${S}"
	# This is how their README's install instructions say to set the 
	# prefixes.  Passing them as parameters to eqmake4 doesn't seem to
	# work.
	qmake -set BEAVER_PREFIX /usr/
	qmake -set BEAVER_LINK_PREFIX /usr/
	eqmake4
	popd
}

src_install() {
	qt4-r2_src_install

	# Thier README install instructions mention that qmake has a bug 
	# that installs binaries with mask 0644.  This is their suggested
	# fix for that.
	einfo "Making sure ${PN} is executable"
	chmod a+x "${D}/usr/bin/${PN}"

	dodoc ENJOY.txt LGPL_EXCEPTION.TXT README README.qtcreator README.txt
}