acerhk-0.5.35-r1.ebuild

acerhk-0.5.35-r1.ebuild (text/plain), 1.50 KB, created by Peter Große on 2010-12-02 19:02:30 UTC

# Copyright 1999-2008 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/app-laptop/acerhk/acerhk-0.5.35.ebuild,v 1.6 2008/06/01 01:25:57 jurek Exp $

EAPI=2
inherit linux-mod

DESCRIPTION="Hotkey driver for some Acer and Acer-like laptops"
HOMEPAGE="http://www.cakey.de/acerhk/"
SRC_URI="http://www.cakey.de/${PN}/archives/${P}.tar.bz2"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~x86"
IUSE=""

pkg_setup() {
	BUILD_PARAMS="KERNELSRC=${KERNEL_DIR}"
	BUILD_TARGETS="all"
	MODULE_NAMES="acerhk(extra:)"

	linux-mod_pkg_setup
}

src_prepare() {
	epatch "${FILESDIR}"/${P}-proc_dir_entry-owner.patch

	if [[ ${KV_MINOR} -eq 6 ]] && [[ ${KV_PATCH} -ge 33 ]]; then
		sed -i -e 's:<linux/config.h>:<generated/autoconf.h>:' acerhk.c || die
		sed -i -e 's:linux/utsrelease.h:generated/utsrelease.h:' Makefile || die
		epatch "${FILESDIR}"/${P}-ioctlfix.patch
	fi

	if [[ ${KV_MINOR} -eq 6 ]] && [[ ${KV_PATCH} -ge 19 ]]; then
		sed -i -e 's:<linux/config.h>:<linux/autoconf.h>:' acerhk.c || die
	fi

	if [[ ${KV_MINOR} -eq 6 ]] && [[ ${KV_PATCH} -ge 24 ]]; then
		sed -i -e 's#^CFLAGS#EXTRA_CFLAGS#g' Makefile || die
	fi
}

src_install() {
	linux-mod_src_install
	dodoc README NEWS
	docinto doc
	dodoc doc/*
}

pkg_postinst() {
	linux-mod_pkg_postinst

	elog "You can load the module:"
	elog "% modprobe acerhk poll=1"
	elog "If you need poll=1 you can set it permanently in /etc/modprobe.d/acerhk"
	elog
	elog "If you need more info about this driver you can read the README file."
}