proposed media-libs/mx-1.0.4.ebuild

mx-1.0.4.ebuild (text/plain), 1.13 KB, created by Alexandre Rostovtsev (RETIRED) on 2010-11-18 05:35:48 UTC

# Copyright 1999-2010 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

EAPI=3

DESCRIPTION="A widget toolkit using Clutter"
HOMEPAGE="http://git.clutter-project.org/mx/"
SRC_URI="http://source.clutter-project.org/sources/mx/1.0/${P}.tar.bz2"

LICENSE="LGPL-2.1"
SLOT="1.0"
KEYWORDS="~amd64 ~x86"
IUSE="+dbus debug doc glade introspection startup-notification"

RDEPEND="media-libs/clutter:1.0[introspection?]
	>=x11-libs/gtk+-2.20:2[introspection?]
	>=x11-libs/libXrandr-1.2.0
	virtual/libiconv
	dbus? ( >=dev-libs/dbus-glib-0.82 )
	glade? ( >=dev-util/glade-3.4.5 )
	introspection? ( >=dev-libs/gobject-introspection-0.6.4 )
	startup-notification? ( >=x11-libs/startup-notification-0.9 )"
DEPEND="${RDEPEND}
	>=dev-util/intltool-0.41.0
	>=dev-util/pkgconfig-0.16
	sys-devel/gettext
	doc? ( >=dev-util/gtk-doc-1.14 )"

src_configure() {
	econf $(use_with dbus) \
		$(use_enable debug) \
		$(use_enable doc gtk-doc) \
		$(use_with glade) \
		$(use_enable introspection) \
		$(use_with startup-notification)
}

src_install() {
	emake install DESTDIR="${D}" || die "Install failed"
	dodoc ChangeLog NEWS README
}