vmware-dsp-1.3.ebuild

vmware-dsp-1.3.ebuild (text/plain), 1.61 KB, created by Samuli Suominen (RETIRED) on 2010-10-28 19:03:05 UTC

# Copyright 1999-2009 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/app-emulation/vmware-dsp/vmware-dsp-1.3.ebuild,v 1.7 2009/11/24 14:32:11 flameeyes Exp $

EAPI=2
inherit eutils multilib toolchain-funcs

MY_P=${PN/-}-${PV}

DESCRIPTION="Allows you to use VMware Workstation with ESD."
HOMEPAGE="http://ftp.cvut.cz/vmware/"
SRC_URI="http://platan.vc.cvut.cz/ftp/pub/vmware/${MY_P}.tar.gz
	http://ftp.cvut.cz/vmware/${MY_P}.tar.gz
	http://ftp.cvut.cz/vmware/obsolete/${MY_P}.tar.gz
	http://knihovny.cvut.cz/ftp/pub/vmware/${MY_P}.tar.gz
	http://knihovny.cvut.cz/ftp/pub/vmware/obsolete/${MY_P}.tar.gz"

LICENSE="LGPL-2"
SLOT="0"
KEYWORDS="-* ~amd64 ~x86"
IUSE="multilib"

RDEPEND="media-sound/esound
	sys-libs/glibc
	multilib? ( amd64? ( app-emulation/emul-linux-x86-soundlibs ) )"
DEPEND="${RDEPEND}"

S=${WORKDIR}/${MY_P}

src_compile() {
	pushd src >/dev/null

	if use x86; then
		emake -C 32 CC="$(tc-getCC)" PLUGINS="libvmdsp_esd.so" -j1 || die
	elif has_multilib_profile; then
		emake -C 64 CC64="$(tc-getCC)" PLUGINS="libvmdsp_esd.so" -j1 || die
		emake -C 32 CC="$(tc-getCC)" PLUGINS="libvmdsp_esd.so" -j1 || die
	else
		emake -C 64 CC64="$(tc-getCC)" PLUGINS="libvmdsp_esd.so" -j1 || die
	fi
	
	popd >/dev/null
}

src_install() {
	if use x86; then
		dolib src/32/libvmdsp*.so || die
	elif has_multilib_profile; then
		exeinto /usr/lib32
		doexe src/32/libvmdsp*.so || die
		dolib src/64/libvmdsp*.so || die
	else
		dolib src/64/libvmdsp*.so || die
	fi

	dobin vmwareesd || die

	make_desktop_entry vmwareesd "VMware Workstation (ESD)" \
		vmware-workstation System
}