sexyspc-0.4.4.ebuild

sexyspc-0.4.4.ebuild (text/plain), 1.55 KB, created by Travis Tilley (RETIRED) on 2004-02-06 14:25:11 UTC

# Copyright 1999-2004 Gentoo Technologies, Inc.
# Distributed under the terms of the GNU General Public License v2

DESCRIPTION="sexyPSF is an open-source PSF file player"
HOMEPAGE="http://xodnizel.net/sexypsf/"
SRC_URI="http://xodnizel.net/sexypsf/sexypsf${PV//./}.tar.gz"
LICENSE="GPL"
SLOT="0"
KEYWORDS="~x86 -amd64 ~ppc ~alpha ~sparc"
IUSE="xmms"

DEPEND="sys-libs/zlib
	xmms? ( >=media-sound/xmms-1.2
		=x11-libs/gtk+-1.2* )"

RDEPEND="${DEPEND}"

S=${WORKDIR}/sexypsf

src_compile() {
	cd ${S}/Linux
	
	# ppc and sparc are big-endian while all other keywords are
	# little-endian (as far as I know)
	use ppc || use sparc && CPU="MSBFIRST" || CPU="LSBFIRST"
	
	# Note: these specific CFLAGS were chosen by the author of this
	# plugin. Since we over-write the default OPTIMIZE with our own
	# CFLAGS and -ffast-math is one optimization that should never
	# be in a global CFLAGS setting, I figured it would be best to
	# include them here.
	OPTIMIZE="-O2 -finline-functions -ffast-math -fno-exceptions \
	${CFLAGS}"

	# and amd64 requires all shared libs to be compiled with -fPIC
	use amd64 && OPTIMIZE="${OPTIMIZE} -fPIC"
	
	# Note 2: The command-line version is marked as being for
	# debugging and testing only. It may not work properly, but we
	# include it here anyway.
	emake CPU="${CPU}" OPTIMIZE="${OPTIMIZE}" || die
	
	use xmms && (
		cd ${S}/xmms
		emake CPU="${CPU}" OPTIMIZE="${OPTIMIZE}" ) || die
}

src_install() {
	cd ${S}/Linux
	dobin sexypsf

	use xmms && (
		cd ${S}/xmms
		insinto `xmms-config --input-plugin-dir`
		doins libsexypsf.so )
	
	dodoc ${S}/Docs/*
}