# Copyright 1999-2010 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

EAPI=3

export CBUILD=${CBUILD:-${CHOST}}
export CTARGET=${CTARGET:-${CHOST}}
if [[ ${CTARGET} == ${CHOST} ]] ; then
	if [[ ${CATEGORY/cross-} != ${CATEGORY} ]] ; then
		export CTARGET=${CATEGORY/cross-}
	fi
fi

inherit eutils flag-o-matic versionator

MY_PV=$(replace_all_version_separators '-')
MY_P=${PN}-${MY_PV}-release

DESCRIPTION="Implementation of pthreads for Win32"
HOMEPAGE="http://sourceware.org/pthreads-win32"
SRC_URI="ftp://sourceware.org/pub/pthreads-win32/${MY_P}.tar.gz"

LICENSE="LGPL-2.1"
SLOT="0"
KEYWORDS="~amd64"

IUSE=""
RESTRICT="strip"

DEPEND=""
RDEPEND="${DEPEND}"

S="${WORKDIR}/${MY_P}"

pkg_setup() {
	if [[ ${CBUILD} == ${CHOST} ]] && [[ ${CHOST} == ${CTARGET} ]] ; then
		die "Invalid configuration; do not emerge this directly"
	fi
}

src_prepare() {
	. "${FILESDIR}"/flag-o-matic.eblit

	filter-flags -fstack-protector
    CHOST=${CTARGET} strip-unsupported-flags

	sed -i GNUmakefile \
		-e '/^OPT/s/-O3 -finline-functions//' \
		-e "/^CFLAGS/s/\$/ ${CFLAGS}/" \
		-e "/^CFLAGS/a\ LFLAGS = ${LDFLAGS} -lwsock32" \
		|| die
}

src_compile() {
	emake CROSS=${CTARGET}- GC || die
}

src_install() {
	insinto /usr/${CTARGET}/usr/lib
	newins libpthreadGC2.a libpthread.a || die
	insinto /usr/${CTARGET}/usr/bin
	doins pthreadGC2.dll || die
	insinto /usr/${CTARGET}/usr/include
	doins {pthread,sched,semaphore}.h || die
}