# Copyright 1999-2010 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/www-plugins/moonlight/moonlight-1.0.1.ebuild,v 1.4 2010/08/31 15:38:33 ssuominen Exp $

EAPI=2

inherit eutils mono multilib nsplugins

DESCRIPTION="Moonlight is an open source implementation of Silverlight"
HOMEPAGE="http://www.go-mono.com/moonlight/"
SRC_URI="ftp://ftp.novell.com/pub/mono/sources/moon/${PV}/${P}.tar.bz2
	ftp://ftp.novell.com/pub/mono/sources/moon/${PV}/mono-2.6.1.tar.bz2
	ftp://ftp.novell.com/pub/mono/sources/moon/${PV}/mono-basic-2.6.tar.bz2"
LICENSE="BSD-4 GPL-2 GPL-2-with-linking-exception IDPL LGPL-2 MIT Ms-PL NPL-1.1"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="alsa curl examples debug nsplugin pulseaudio sdk test"
RESTRICT="mirror"

RDEPEND="
	curl? ( net-misc/curl )
	>=x11-libs/gtk+-2.14
	>=dev-libs/glib-2.18
	>=x11-libs/cairo-1.8.4
	>=media-video/ffmpeg-0.4.9_p20090121
	>=net-libs/xulrunner-1.9.1:1.9
	x11-libs/libXrandr
	alsa? ( >=media-libs/alsa-lib-1.0.18 )
	pulseaudio? ( >=media-sound/pulseaudio-0.9.14 )
	>=media-libs/freetype-2.3.7
	>=media-libs/fontconfig-2.6.0
	>=dev-lang/mono-2.6.1[moonlight]
	>=dev-dotnet/gtk-sharp-2.12.9
	dev-dotnet/wnck-sharp
	dev-dotnet/rsvg-sharp"
DEPEND="${RDEPEND}
	>=dev-util/pkgconfig-0.23
	dev-libs/expat"

src_configure() {
	econf	--enable-shared \
		--disable-static \
	 	--with-cairo=system \
		--with-ffmpeg=yes \
		--with-ff3=yes \
		--without-ff2 \
		--enable-desktop-support \
		--with-curl=$(use !curl && printf "no" || printf "system" ) \
		--with-mcspath="${WORKDIR}/mono-2.6.1/mcs" \
		--with-mono-basic-path="${WORKDIR}/mono-basic-2.6" \
		$(use_enable nsplugin browser-support) \
		$(use_enable sdk) \
		$(use_with alsa) \
		$(use_with pulseaudio) \
		$(use_with debug) \
		$(use_with test testing) \
		$(use_with test performance) \
		$(use_with examples) \
		|| die "econf failed"
}

src_install() {
	emake DESTDIR="${D}" install || die "emake install failed"
	inst_plugin /usr/$(get_libdir)/moon/plugin/libmoonloader.so || die "installing libmoonloader failed"
	find "${D}" -name '*.la' -exec rm -rf '{}' '+' || die "la removal failed"
}