# Copyright 1999-2010 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/sci-biology/ncbi-tools++/ncbi-tools++-2009.05.15-r6.ebuild,v 1.1 2010/06/26 11:04:59 jlec Exp $

EAPI="3"

inherit eutils flag-o-matic multilib toolchain-funcs

MY_TAG="Jun_15_2010"
MY_Y="${MY_TAG/*_/}"
MY_P="ncbi_cxx--${MY_TAG}"

DESCRIPTION="NCBI C++ Toolkit, including NCBI BLAST+"
HOMEPAGE="http://www.ncbi.nlm.nih.gov/books/bv.fcgi?rid=toolkit"
SRC_URI="ftp://ftp.ncbi.nih.gov/toolbox/ncbi_tools++/${MY_Y}/${MY_TAG}/${MY_P}.tar.gz"

LICENSE="public-domain"
SLOT="0"
#IUSE="X unicode opengl gnutls test"
IUSE="sqlite"
KEYWORDS="~amd64 ~x86 ~amd64-linux ~x86-linux"

DEPEND="sqlite? ( dev-db/sqlite:3 )
        sys-libs/zlib
		app-arch/bzip2
		dev-libs/lzo
		dev-libs/libpcre
		net-libs/gnutls
		dev-libs/openssl
        dev-db/freetds
		virtual/mysql
		x11-libs/fltk
		media-libs/mesa
		media-libs/freetype
		dev-libs/xalan-c"	
RDEPEND="${DEPEND}"

S="${WORKDIR}/${MY_P}"

src_prepare() {
	#epatch "${FILESDIR}"/${P}-gcc44.patch \
#		"${FILESDIR}"/${P}-asneeded.patch
	sed -i -e 's/-print-file-name=libstdc++.a//' \
		-e '/sed/ s/\([gO]\[0-9\]\)\*/\1\\+/' \
		src/build-system/configure || die
}

src_configure() {
	# required with gcc-4.4 and code turned on by --with-mt
	append-cxxflags -fpermissive

	tc-export CXX CC

	"${S}"/configure --without-debug \
		--with-bin-release \
		--with-bincopy \
		--without-static \
		--with-dll \
		--with-mt \
		--prefix="${ED}"/usr \
		--libdir="${ED}"/usr/$(get_libdir)/${PN} \
		|| die

}

src_compile() {
	emake all_r -C GCC*-Release*/build || die
}

src_install() {
	emake install || die
	# File collisions with sci-biology/ncbi-tools
	rm -f "${ED}"/usr/bin/{asn2asn,rpsblast,test_regexp}

	echo "LDPATH=${EPREFIX}/usr/$(get_libdir)/${PN}" > ${S}/99${PN}
	doenvd "${S}/99${PN}"
}

pkg_postinst() {
	einfo 'Please run "source /etc/profile" before using this package in the current shell.'
}