# ask for compliance

.POSIX:

# must be passed to CC when it'll call the linker

.SUFFIXES: .c .o

.c.o:

	$(CC) $(CFLAGS) $(CPPFLAGS) -c $<

dnl Process this file with autoconf to produce a configure script.

AC_INIT([oer], [1.0.66])

AC_CONFIG_SRCDIR([oer.c])

AC_CONFIG_HEADER([config.h])

dnl This is the default destination

AC_PREFIX_DEFAULT([$HOME/oer])

dnl Checks for programs.

AC_PROG_CC

AC_PROG_MAKE_SET

AC_PROG_INSTALL

dnl we need uname

AC_CHECK_PROG(UNAME,uname,uname)

AC_ARG_ENABLE(debug, [AS_HELP_STRING([--enable-debug], [enable runtime debugging (You should also set CFLAGS="-g")])], [debug=$enableval], [debug=no])

AC_ARG_ENABLE(opt, [AS_HELP_STRING([--disable-opt], [disable automatic setting of optimization compiler switches])], [opt="$enableval"], [opt=yes])

AC_ARG_ENABLE([strip], [AS_HELP_STRING([--disable-strip], [Disable automatic stripping of binaries])], [enable_strip="$enableval"], [enable_strip=yes])

AC_MSG_CHECKING(system type)

SYSTEM_TYPE=`${UNAME}`

AC_MSG_RESULT($SYSTEM_TYPE)

IRIX=no

AS_IF([test "x$SYSTEM_TYPE" = "xIRIX"],

	[IRIX=yes

	enable_strip=no

	])

AS_IF([test "$debug" = "yes"],

	[AC_DEFINE([DEBUG], [], [Add debugging codepaths])])

dnl for devs...

MYCFLAGSADDGCC="-Wstrict-prototypes -Wall"

dnl strip binaries by default

AS_IF([test "$enable_strip" = "yes" -a "x$IRIX" = "xno"],

	[MYLDFLAGSADDCC="$MYLDFLAGSADDCC -s"

	MYLDFLAGSADDGCC="$MYLDFLAGSADDGCC -s"])

AS_IF([test "$opt" = "yes"],

	[MYCFLAGSADDCC="$MYCFLAGSADDCC -O"

	MYCFLAGSADDGCC="$MYCFLAGSADDGCC -O2"])

dnl system specific compile settings

if test "x${SYSTEM_TYPE}" = "xHP-UX"; then

  MYCFLAGSADDCC="${MYCFLAGSADDCC} -Ae"

fi

if test "x${SYSTEM_TYPE}" = "xOSF1"; then

  MYCFLAGSADDCC="${MYCFLAGSADDCC} -std -no_intrinsics"

fi

dnl newer SunOS/Solaris have different signal() behaviour

if test "x${SYSTEM_TYPE}" = "xSunOS"; then

	AC_DEFINE([NEW_SIGNALS], [], [Support Solaris's signal() behaviour])

fi

if test "x$IRIX" = "xIRIX"; then

  MYCFLAGSADDCC="$MYCFLAGSADDCC -std -no_intrinsics"

fi

dnl Append compiler CFLAGS and LDFLAGS

dnl assume gcc. Checking x$CC = xgcc is not enough -- there's ${HOST}-gcc, for example...

dnl Check that compiler works with the flags we've generated, falling

dnl back from GCC flags -> generic/system-specific flags -> no flags.

CFLAGS_save="$CFLAGS"

CPPFLAGS_save="$CPPFLAGS"

LDFLAGS_save="$LDFLAGS"

dnl GCC

CFLAGS="$CFLAGS_save $MYCFLAGSADDGCC"

LDFLAGS="$LDFLAGS_save $MYLDFLAGSADDGCC"

AC_COMPILE_IFELSE(

	[AC_LANG_PROGRAM(

		[[#include <stdio.h>]],

		[[fprintf(stderr, "Hello, gcc world!\n");]])],

	[:],

	[

	dnl system-specific/generic

	CFLAGS="$CFLAGS_save $MYCFLAGSADDCC"

	LDFLAGS="$LDFLAGS_save $MYLDFLAGSADDCC"

	AC_COMPILE_IFELSE(

		[AC_LANG_PROGRAM(

			[[#include <stdio.h>]],

			[[fprintf(stderr, "Hello, system-specific world!\n");]])],

		[:],

		[

		dnl no flags (user flags only)

		CFLAGS="$CFLAGS_save"

		LDFLAGS="$LDFLAGS_save"])])

dnl Find out source code size

LINES=`wc -l *.h *.c | tail -1 | sed 's/total/\ /' | tr -d ' '`

CHARS=`wc -c *.h *.c | tail -1 | sed 's/total/\ /' | tr -d ' '`

dnl export to config.h

AC_DEFINE_UNQUOTED(SOURCE_LINES,${LINES},[Number of source lines])

AC_DEFINE_UNQUOTED(SOURCE_CHARS,${CHARS},[Number of characters in the source])

dnl Checks for libraries (except IRIX)

if test "${IRIX}" = "no"; then

  AC_CHECK_LIB(crypt,crypt)

  AC_CHECK_LIB(socket,socket)

  AC_CHECK_LIB(nsl,connect)

  AC_CHECK_LIB(dns,gethostbyname)

  AC_CHECK_LIB(dl,dlopen)

fi

dnl Checks for header files.

AC_HEADER_STDC

AC_CHECK_HEADERS(fcntl.h sys/time.h unistd.h strings.h crypt.h)

dnl FreeBSD doesn't like ctype.h to be included, why only The Red Devil knows 

if test "x${SYSTEM_TYPE}" != "xFreeBSD"; then  

  AC_CHECK_HEADERS(ctype.h)

else

  AC_MSG_WARN([

  Disabling ctype.h because of FreeBSD. You can safely

  ignore the implicit declaration of function isxxxxx messages.

  ]) 

fi

dnl check for uname

AC_CHECK_FUNCS(uname)

dnl check for getaddrinfo

AC_CHECK_FUNCS(getaddrinfo)

if test "${ac_cv_func_getaddrinfo}" = "no"; then

	AC_MSG_ERROR([

  Your system does not support the getaddrinfo function call.

  (you could try oer 1.0-62 or older.)

])

fi

dnl check for locale

AC_CHECK_HEADERS(locale.h)

dnl Checks for typedefs, structures, and compiler characteristics.

AC_C_CONST

AC_TYPE_SIZE_T

AC_HEADER_TIME

AC_STRUCT_TM

dnl Checks for library functions.

AC_TYPE_SIGNAL

AC_CHECK_FUNCS(snprintf)

if test "${ac_cv_func_snprintf}" = "no"; then

	AC_MSG_WARN([

  Your system does not have snprintf, using unsafe vsprintf alternative

])

fi

AC_CHECK_FUNCS(vsprintf)

if test "${ac_cv_func_vsprintf}" = "no"; then

	AC_MSG_ERROR([

  Your system does not even have vsprintf. Get a real system!

])

fi

AC_CHECK_FUNCS(vfprintf)

if test "${ac_cv_func_vfprintf}" = "no"; then

	AC_MSG_ERROR([

  Your system does not have vfprintf. Get a real system!

])

fi

AC_CONFIG_FILES([

	Makefile

	])

AC_OUTPUT

AC_MSG_RESULT([

  Type "make" to compile oer

])