Updated suggested ebuild

milkytracker-0.90.85.ebuild (text/plain), 1.08 KB, created by Kim Nilsson on 2010-08-15 09:06:28 UTC

# Copyright 1999-2010 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

EAPI="2"
inherit autotools eutils

DESCRIPTION="FastTracker 2 inspired music tracker"
HOMEPAGE="http://milkytracker.org/"
SRC_URI="http://www.milkytracker.org/files/${P}.tar.bz2"

LICENSE="GPL-3"
SLOT="0"
KEYWORDS="~ppc"
IUSE="alsa jack"

RDEPEND=">=media-libs/libsdl-1.2
	alsa? ( media-libs/alsa-lib )
	jack? ( media-sound/jack-audio-connection-kit )"
DEPEND="${RDEPEND}"

src_unpack() {
	unpack ${A}
	cd "${S}"

	epatch "${FILESDIR}/${P}-doc_fix.patch"
	epatch "${FILESDIR}/${P}-64bit_freebsd_fix.patch"
	epatch "${FILESDIR}/${P}-jack_autoconnect.patch"
	epatch "${FILESDIR}/${P}-no_zziplib_dep.patch"
	eautoreconf
}

src_configure() {
	econf $(use_with alsa) $(use_with jack) || die "econf failed"
}

src_install() {
	emake DESTDIR="${D}" install || die "emake install failed"

	dodoc AUTHORS docs/readme_unix
	dohtml docs/{MilkyTracker,FAQ,ChangeLog}.html

	newicon resources/pictures/carton.png ${PN}.png
	make_desktop_entry ${PN} MilkyTracker ${PN} \
		"AudioVideo;Audio;Sequencer"
}