ts (moreutils) ebuild

ts-0.39.ebuild (text/plain), 1.14 KB, created by Nick Howell on 2010-07-18 16:33:57 UTC

# Copyright 1999-2010 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/sys-apps/moreutils/moreutils-0.39.ebuild,v 1.1 2010/03/26 08:16:24 ssuominen Exp $

EAPI=2
inherit eutils toolchain-funcs

DESCRIPTION="ts from a growing collection of the unix tools that nobody thought to write
thirty years ago"
HOMEPAGE="http://kitenet.net/~joey/code/moreutils/"
MONOLITHIC_PN="moreutils"
SRC_URI="mirror://debian/pool/main/${MONOLITHIC_PN:0:1}/${MONOLITHIC_PN}/${MONOLITHIC_PN}_${PV}.tar.gz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~hppa ~x86"
IUSE=""

RDEPEND="!<=sys-apps/moreutils-0.39
	
	
	"
DEPEND="${RDEPEND}
	>=app-text/docbook2X-0.8.8-r2
	app-text/docbook-xml-dtd:4.4"

S=${WORKDIR}/${MONOLITHIC_PN}

src_prepare() { 
	sed -i -e 's/BINS=.*/BINS=/' \
		-e 's/PERLSCRIPTS=.*/PERLSCRIPTS=ts/' \
		-e 's/MANS=.*/MANS=ts.1/' \
		-e 's/^\s*\$(INSTALL_BIN) \$(BINS).*//' Makefile

	epatch "${FILESDIR}"/${PN}-0.30-dtd-path.patch
}

src_compile() {
	tc-export CC
	emake CFLAGS="${CFLAGS}" DOCBOOK2XMAN=docbook2man.pl || die
}

src_install() {
	emake DESTDIR="${D}" INSTALL_BIN=install install || die
}