# Copyright 1999-2010 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

EAPI=2
PYTHON_DEPEND="2:2.5"

inherit distutils python

DESCRIPTION="Toolkit to convert between many translation formats"
HOMEPAGE="http://translate.sourceforge.net"
SRC_URI="mirror://sourceforge/translate/${P}.tar.bz2"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64"
IUSE="doc html psyco subtitles"

RDEPEND="|| ( >=dev-lang/python-2.5[sqlite] >=dev-python/pysqlite-2 )
	app-text/iso-codes
	dev-python/lxml
	psyco? ( dev-python/psyco )
	dev-python/python-levenshtein
	html? ( dev-python/utidylib )
	dev-python/vobject
	subtitles? ( media-video/gaupol )
	sys-devel/gettext"
	# dev-python/iniparse is missing in Portage

PYTHON_MODNAME=translate

src_install() {
	dohtml translate/doc/{index.html,README,user} -r || die
	use doc && dohtml translate/doc/api -r
	rm -Rf translate/doc || die

	distutils_src_install

	if ! use subtitles; then 
		rm "${D}"/usr/bin/sub2po || die
		rm "${D}"/usr/bin/po2sub || die
	fi
	if ! use html; then
		rm "${D}"/usr/bin/html2po || die
		rm "${D}"/usr/bin/po2html || die
	fi

	# there is no dev-python/iniparse in the tree
	rm "${D}"/usr/bin/ini2po || die
	rm "${D}"/usr/bin/po2ini || die

	ebegin "Creating man pages"
	for file in "${D}"/usr/bin/*; do
		filename=$(basename "${file}")

		# lookupclient.py, pocount, build_tmdb, tmserver and the bash scripts don't have man pages
		[[ "${filename}" == "lookupclient.py" ]] && continue
		[[ "${filename}" == "pocount" ]] && continue
		[[ "${filename}" == "build_tmdb" ]] && continue
		[[ "${filename}" == "tmserver" ]] && continue
		head -n 1 "${file}" | grep -F "python" > /dev/null || continue

		PYTHONPATH=${WORKDIR}/${PF}:${PYTHONPATH} ${file} --man > "${T}/${filename}.1" || die "${file} --man failed."
		doman "${T}/${filename}.1"
	done
	eend
}