Modified ebuild

upp-2361-r1.ebuild (text/plain), 1.28 KB, created by Attila Tóth on 2010-07-05 22:02:38 UTC

# Copyright 1999-2010 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

inherit eutils toolchain-funcs

DESCRIPTION="Ultimate++ is a C++ cross-platform rapid application development framework"
HOMEPAGE="http://www.ultimatepp.org/"
SRC_URI="http://downloads.sourceforge.net/project/${PN}/${PN}/${PV}/${PN}-x11-src-${PV}.tar.gz"

LICENSE="BSD"
SLOT="0"
KEYWORDS="~amd64 x86"
IUSE=""

DEPEND="dev-libs/atk
	dev-libs/expat
	dev-libs/glib
	media-libs/freetype
	x11-libs/cairo
	x11-libs/gtk+
	x11-libs/libnotify
	x11-libs/libXinerama
	x11-libs/pango"
RDEPEND="${DEPEND}"

S=${WORKDIR}/${PN}-x11-src-${PV}

src_compile () {
	epatch "${FILESDIR}"/${P}-dwokfur.patch
	local libs_used="x11 freetype2 gtk+-2.0 glib-2.0 cairo pango atk"
	emake -C uppsrc \
		LIBPATH="$($(tc-getPKG_CONFIG) --libs-only-L ${libs_used})" \
		CINC="-I. $($(tc-getPKG_CONFIG) --cflags ${libs_used})" \
		CXX="$(tc-getCXX)" \
		CFLAGS="${CFLAGS}" \
		CXXFLAGS="${CXXFLAGS}" \
		LDFLAGS="${LDFLAGS}" \
		|| die "make failed"
}

src_install () {
	newbin uppsrc/ide.out theide || die
	rm -rf uppsrc/_out || die
	insinto /usr/share/${PN}
	doins GCC.bm || die
	doins -r bazaar examples reference tutorial uppsrc || die
	make_desktop_entry theide TheIDE /usr/share/${PN}/uppsrc/ide/theide-48.png
}