# Copyright 1999-2003 Gentoo Technologies, Inc.
# Distributed under the terms of the GNU General Public License v2
# $Header: $ 

inherit games

S="${WORKDIR}/${PN}-i386-${PV}"
DESCRIPTION="a cool Liero clone."
HOMEPAGE="http://www.bankiz.org"
SRC_URI="http://www.bankiz.org/downloads/${PN}-i386-${PV}.tar.bz2"

KEYWORDS="~x86"
LICENSE="GPL-2"
SLOT="0"
IUSE=""

DEPEND="media-libs/sdl-image
	media-libs/sdl-mixer
	media-libs/sdl-net
	media-libs/sdl-ttf
	>=sys-apps/sed-4"

src_unpack() {
	unpack ${A}

	sed -i \
		-e 's,client\.conf,'${GAMES_SYSCONFDIR}'/'${PN}'/client\.conf,g' \
		-e 's,ddserver\.conf,'${GAMES_SYSCONFDIR}'/'${PN}'/ddserver\.conf,g' \
		-e 's,sound/,'${GAMES_DATADIR}'/'${PN}'/sound/,g'	\
		-e 's,"\([^"]*\)\.ttf","'${GAMES_DATADIR}'/'${PN}'/fonts/\1.ttf",g' \
		-e 's,"\([^"]*\.\(png\|gif\|bmp\)\)","'${GAMES_DATADIR}'/'${PN}'/images/\1",g' \
		-e 's,maps/,'${GAMES_DATADIR}'/'${PN}'/maps/,g' \
		-e 's,maplist\.txt,'${GAMES_DATADIR}'/'${PN}'/maps/maplist\.txt,g' \
		${S}/src/{client,ddserver,common}/* || die "Path fixing failed"
	
}

src_compile() {
	cd "${S}/src/client"
	emake clean || die
	emake		|| die "emake failed (client)"
	cd "${S}/src/ddserver"
	emake clean	|| die
	emake		|| die "emake failed (server)"
	
}

src_install() {
	newgamesbin	bin/bankiz-client.exe bankiz-client \
		|| die "newgamesbin failed (client)"
	newgamesbin	bin/bankiz-server.exe bankiz-server \
		|| die "newgamesbin failed (server)"
	dodir ${GAMES_DATADIR}/${PN}/{sound,images,fonts,maps} \
		${GAMES_SYSCONFDIR}/${PN} \
			|| die "dodir failed"
	cp bin/{*.png,*.bmp,*.gif} ${D}/${GAMES_DATADIR}/${PN}/images/ \
		|| die "cp failed (images)"
	cp bin/sound/* ${D}/${GAMES_DATADIR}/${PN}/sound/ \
		|| die "cp failed (sound)"
	cp bin/*.ttf ${D}/${GAMES_DATADIR}/${PN}/fonts/ \
		|| die "cp failed (fonts)"
	cp bin/{maplist.txt,maps/*.*} ${D}/${GAMES_DATADIR}/${PN}/maps/ \
		|| die "cp failed (maps)"
	cp bin/{client.conf,ddserver.conf} ${D}/${GAMES_SYSCONFDIR}/${PN}/ \
		|| die "cp failed (conf)"
	fperms 664 ${GAMES_SYSCONFDIR}/${PN}/client.conf || die "fperms failed"

	find ${D}/${GAMES_DATADIR}/ -type f | xargs chmod a-x

	dodoc README || die "dodoc failed"
	dohtml doc/* || die "dohtml failed"
	prepgamesdirs
}