# Copyright 1999-2010 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/games-fps/duke3d-data/duke3d-data-1.0.ebuild,v 1.5 2010/04/26 11:55:23 fauli Exp $

inherit eutils games

DESCRIPTION="Duke Nukem 3D data files"
HOMEPAGE="http://www.3drealms.com/"
SRC_URI=""

LICENSE="DUKE3D"
SLOT="0"
KEYWORDS="amd64 hppa ppc x86"
IUSE=""
PROPERTIES="interactive"

DEPEND=""
RDEPEND="|| ( games-fps/duke3d games-fps/eduke32 )"

S=${WORKDIR}

src_unpack() {
	export CDROM_NAME_SET=("Existing Install" "Duke Nukem 3D CD" "Duke Nukem 3D Atomic Edition CD")
	cdrom_get_cds duke3d.grp:dvd/dn3dinst/duke3d.grp:atominst/duke3d.grp

	if [[ ${CDROM_SET} -ne 0 && ${CDROM_SET} -ne 1 && ${CDROM_SET} -ne 2 ]] ; then
		die "Error locating data files.";
	fi
}

src_install() {
	local DATAROOT

	case ${CDROM_SET} in
	0) DATAROOT= ;;
	1) DATAROOT="dn3dinst/" ;;
	2) DATAROOT="atominst/" ;;
	esac

	if [ -d "${GAMES_DATADIR}/duke3d" ]; then
		insinto "${GAMES_DATADIR}/duke3d"
	elif [ -d "${GAMES_DATADIR}/eduke32" ]; then
		insinto "${GAMES_DATADIR}/eduke32"
	else
		die "game engine not detected"
	fi
	doins "${CDROM_ROOT}"/$DATAROOT/{*.grp,*.rts,*.con,*.dmo} \
		|| die "doins failed"
	dodoc "${CDROM_ROOT}"/$DATAROOT/*.doc
	prepgamesdirs
}