opencv 2.1.0 ebuild

opencv-2.1.0.ebuild (text/plain), 2.62 KB, created by Gijs Molenaar on 2010-06-20 13:51:43 UTC

# Copyright 1999-2010 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/media-libs/opencv/opencv-2.0.0-r1.ebuild,v 1.6 2010/06/16 16:38:21 ssuominen Exp $

EAPI=2
inherit cmake-utils flag-o-matic

MY_P=OpenCV-${PV}

DESCRIPTION="A collection of algorithms and sample code for various computer vision problems."
HOMEPAGE="http://opencv.willowgarage.com"
SRC_URI="mirror://sourceforge/${PN}library/${MY_P}.tar.bz2"

LICENSE="v4l? ( GPL-2 ) xine? ( GPL-2 ) BSD"
SLOT="0"
KEYWORDS="~amd64 ~ppc ~ppc64 ~x86 ~x86-macos ~x64-macos"
IUSE="debug deprecated examples ffmpeg gstreamer gtk ieee1394 ipp jpeg jpeg2k
octave tbb png python sse sse2 sse3 test tiff v4l xine numpy aqua"

RDEPEND="sys-libs/zlib
	ipp? ( sci-libs/ipp )
	python? ( >=dev-lang/python-2.5
		deprecated? ( dev-lang/swig )
        numpy? ( dev-python/numpy ) )
	ieee1394? ( sys-libs/libraw1394
		media-libs/libdc1394:2 )
	ffmpeg? ( >=media-video/ffmpeg-0.5 )
	gstreamer? ( media-libs/gstreamer )
	gtk? ( x11-libs/gtk+:2 )
	jpeg2k? ( media-libs/jasper )
	jpeg? ( media-libs/jpeg )
	png? ( media-libs/libpng )
	tiff? ( media-libs/tiff )
	xine? ( media-libs/xine-lib )
	octave? ( sci-mathematics/octave
		dev-lang/swig )
    tbb? ( dev-cpp/tbb )"

DEPEND="${RDEPEND}
	dev-util/pkgconfig"

S=${WORKDIR}/${MY_P}

PATCHES=(
    "${FILESDIR}/osx.patch"
)


src_configure() {
	mycmakeargs=(
        "-DCMAKE_VERBOSE_MAKEFILE=ON"
		"-DCMAKE_SKIP_RPATH=ON"
		$(cmake-utils_use_build examples)
		$(cmake-utils_use_build python NEW_PYTHON_SUPPORT)
		$(cmake-utils_use_build octave OCTAVE_SUPPORT)
		$(cmake-utils_use_build test TESTS)

		$(cmake-utils_use ipp)
		"-DUSE_O3=OFF"
		"-DUSE_OMIT_FRAME_POINTER=OFF"

        ## these should be true when aqua is disabled (osx 32bit mode)
        "-DWITH_CARBON=OFF"
        "-DWITH_QUICKTIME=OFF"

    	$(cmake-utils_use_enable sse)
		$(cmake-utils_use_enable sse2)
		$(cmake-utils_use_enable sse3)
		$(cmake-utils_use_enable sse3 SSSE3)

        $(cmake-utils_use_with tbb)
		$(cmake-utils_use_with ieee1394 1394)
		$(cmake-utils_use_with ffmpeg)
		$(cmake-utils_use_with gstreamer)
		$(cmake-utils_use_with gtk)
		$(cmake-utils_use_with jpeg2k jasper)
		$(cmake-utils_use_with jpeg)
		$(cmake-utils_use_with png)
		$(cmake-utils_use_with tiff)
		$(cmake-utils_use_with v4l)
		$(cmake-utils_use_with xine)
		"-DWITH_UNICAP=OFF"
		)

	if use python; then
		mycmakeargs+=(
			$(cmake-utils_use_build deprecated SWIG_PYTHON_SUPPORT)

            ##there is no flag to enable or disable numpy, opencv just checks if numpy is available
			#$(cmake-utils_use_build numpy ENABLE_NUMPY)
			)
	fi

	cmake-utils_src_configure
}