reworked ebuild, solved problem with keeping sources

mplayer-git-9999.ebuild (text/plain), 22.17 KB, created by Nikoli on 2010-06-02 16:17:49 UTC

# Copyright 1999-2010 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

EAPI="2"

EGIT_REPO_URI="git://repo.or.cz/mplayer-build.git"
EGIT_HAS_SUBMODULES="true"
[[ ${PV} = *9999* ]] && VCS_ECLASS="git" || VCS_ECLASS=""

inherit eutils flag-o-matic multilib base ${VCS_ECLASS}

[[ ${PV} != *9999* ]] && MPLAYER_REVISION="GIT-r31871"

namesuf="${PN/mplayer/}"

IUSE="3dnow 3dnowext +a52 aalib +alsa altivec +ass bidi bindist bl bs2b
+cddb +cdio cdparanoia cpudetection custom-cpuopts custom-cflags debug dga +dirac directfb
doc +dts +dv dvb +dvd +dvdnav dxr3 +enca +encode esd +faac +faad fbcon ftp
gif ggi gsm +iconv ipv6 jack joystick jpeg jpeg2k kernel_linux ladspa
libcaca lirc +live lzo mad md5sum +mmx mmxext mng +mp3 nas +network nut
amr +opengl +osdmenu oss png pnm pulseaudio pvr +quicktime radio +rar +real +rtc
samba +shm +schroedinger +hardcoded-tables sdl +speex sse sse2 ssse3 svga tga +theora +tremor
+truetype +toolame +twolame +unicode v4l v4l2 vdpau vidix vpx +vorbis win32codecs
+X +x264 xanim xinerama +xscreensaver +xv +xvid xvmc zoran
+ffmpeg-mt -external-ffmpeg symlink"

VIDEO_CARDS="s3virge mga tdfx vesa"
for x in ${VIDEO_CARDS}; do
	IUSE+=" video_cards_${x}"
done

BLUV="1.7"
SVGV="1.9.17"
AMR_URI="http://www.3gpp.org/ftp/Specs/archive"
FONT_URI="
	mirror://mplayer/releases/fonts/font-arial-iso-8859-1.tar.bz2
	mirror://mplayer/releases/fonts/font-arial-iso-8859-2.tar.bz2
	mirror://mplayer/releases/fonts/font-arial-cp1250.tar.bz2
"
if [[ ${PV} == *9999* ]]; then
	RELEASE_URI=""
else
	RELEASE_URI="mirror://gentoo/${P}.tar.lzma"
fi
SRC_URI="${RELEASE_URI}
	!truetype? ( ${FONT_URI} )
	svga? (	mirror://gentoo/svgalib_helper-${SVGV}-mplayer.tar.gz )"

DESCRIPTION="Media Player for Linux"
HOMEPAGE="http://www.mplayerhq.hu/"

FONT_RDEPS="
	virtual/ttf-fonts
	media-libs/fontconfig
	>=media-libs/freetype-2.2.1:2
"
X_RDEPS="
	x11-libs/libXext
	x11-libs/libXxf86vm
"
# Rar: althrought -gpl version is nice, it cant do most functions normal rars can
#	nemesi? ( net-libs/libnemesi )
RDEPEND+="
	sys-libs/ncurses
	app-arch/bzip2
	sys-libs/zlib
	!bindist? (
		x86? (
			win32codecs? ( media-libs/win32codecs )
		)
	)
	X? (
		${X_RDEPS}
		dga? ( x11-libs/libXxf86dga )
		ggi? (
			media-libs/libggi
			media-libs/libggiwmh
		)
		opengl? ( virtual/opengl )
		vdpau? ( || ( x11-libs/libvdpau >=x11-drivers/nvidia-drivers-180.51 ) )
		xinerama? ( x11-libs/libXinerama )
		xscreensaver? ( x11-libs/libXScrnSaver )
		xv? (
			x11-libs/libXv
			xvmc? ( x11-libs/libXvMC )
		)
	)
	a52? ( media-libs/a52dec )
	aalib? ( media-libs/aalib )
	alsa? ( media-libs/alsa-lib )
	ass? ( ${FONT_RDEPS} media-libs/libass )
	bidi? ( dev-libs/fribidi )
	bs2b? ( media-libs/libbs2b )
	cdio? ( dev-libs/libcdio )
	cdparanoia? ( !cdio? ( media-sound/cdparanoia ) )
	directfb? ( dev-libs/DirectFB )
	dts? ( media-libs/libdca )
	dv? ( media-libs/libdv )
	dvb? ( media-tv/linuxtv-dvb-headers )
	dvd? (
		>=media-libs/libdvdread-4.1.3
		dvdnav? ( >=media-libs/libdvdnav-4.1.3 )
	)
	encode? (
		!twolame? ( toolame? ( media-sound/toolame ) )
		twolame? ( media-sound/twolame )
		faac? ( media-libs/faac )
		mp3? ( media-sound/lame )
		x264? ( >=media-libs/x264-0.0.20100423 )
		xvid? ( media-libs/xvid )
	)
	esd? ( media-sound/esound )
	enca? ( app-i18n/enca )
	faad? ( media-libs/faad2 )
	gif? ( media-libs/giflib )
	iconv? ( virtual/libiconv )
	jack? ( media-sound/jack-audio-connection-kit )
	jpeg? ( media-libs/jpeg )
	ladspa? ( media-libs/ladspa-sdk )
	libcaca? ( media-libs/libcaca )
	lirc? ( app-misc/lirc )
	live? ( media-plugins/live )
	lzo? ( >=dev-libs/lzo-2 )
	mad? ( media-libs/libmad )
	mng? ( media-libs/libmng )
	nas? ( media-libs/nas )
	nut? ( >=media-libs/libnut-661 )
	png? ( media-libs/libpng )
	pnm? ( media-libs/netpbm )
	pulseaudio? ( media-sound/pulseaudio )
	rar? (
		|| (
			app-arch/unrar
			app-arch/rar
		)
	)
	samba? ( net-fs/samba )
	sdl? ( media-libs/libsdl )
	speex? ( media-libs/speex )
	svga? ( media-libs/svgalib )
	theora? ( media-libs/libtheora[encode?] )
	truetype? ( ${FONT_RDEPS} )
	vorbis? ( media-libs/libvorbis )
	xanim? ( media-video/xanim )
	external-ffmpeg? (
		>=media-video/ffmpeg-9999[amr?,dirac?,gsm?,hardcoded-tables?,jpeg2k?,schroedinger?,vpx?]
	encode? (
			media-video/ffmpeg[faac?,mp3?,vorbis?,theora?,x264?,xvid?]
		)
	)
	!external-ffmpeg? (
		amr? ( media-libs/opencore-amr )
		dirac? ( media-video/dirac )
		gsm? ( >=media-sound/gsm-1.0.12-r1 )
		jpeg2k? ( >=media-libs/openjpeg-1.3-r2 )
		schroedinger? ( media-libs/schroedinger )
		vpx? ( media-libs/libvpx )
	)
"

X_DEPS="
	x11-proto/videoproto
	x11-proto/xf86vidmodeproto
"
ASM_DEP="dev-lang/yasm"
DEPEND="${RDEPEND}
	dev-util/pkgconfig
	dev-lang/python
	X? (
		${X_DEPS}
		dga? ( x11-proto/xf86dgaproto )
		dxr3? ( media-video/em8300-libraries )
		xinerama? ( x11-proto/xineramaproto )
		xscreensaver? ( x11-proto/scrnsaverproto )
	)
	amd64? ( ${ASM_DEP} )
	doc? ( dev-libs/libxslt
		app-text/docbook-xsl-stylesheets )
	x86? ( ${ASM_DEP} )
	x86-fbsd? ( ${ASM_DEP} )
"

SLOT="0"
LICENSE="GPL-2"
if [[ ${PV} != *9999* ]]; then
	KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~ppc ~ppc64 ~sparc ~x86 ~x86-fbsd"
else
	KEYWORDS=""
fi

PATCHES=(
)

pkg_setup() {
	if [[ ${PV} == *9999* ]]; then
		elog ""
		elog "This is a live ebuild which installs the latest from upstream's"
		elog "git repository, and is unsupported by Gentoo."
		elog "Everything but bugs in the ebuild itself will be ignored."
		elog ""
	fi

	if use cpudetection; then
		ewarn ""
		ewarn "You've enabled the cpudetection flag.  This feature is"
		ewarn "included mainly for people who want to use the same"
		ewarn "binary on another system with a different CPU architecture."
		ewarn "MPlayer will already detect your CPU settings by default at"
		ewarn "buildtime; this flag is used for runtime detection."
		ewarn "You won't need this turned on if you are only building"
		ewarn "mplayer for this system.  Also, if your compile fails, try"
		ewarn "disabling this use flag."
	fi

	if use custom-cpuopts; then
		ewarn ""
		ewarn "You are using the custom-cpuopts flag which will"
		ewarn "specifically allow you to enable / disable certain"
		ewarn "CPU optimizations."
		ewarn ""
		ewarn "Most desktop users won't need this functionality, but it"
		ewarn "is included for corner cases like cross-compiling and"
		ewarn "certain profiles.  If unsure, disable this flag and MPlayer"
		ewarn "will automatically detect and use your available CPU"
		ewarn "optimizations."
		ewarn ""
		ewarn "Using this flag means your build is unsupported, so"
		ewarn "please make sure your CPU optimization use flags (3dnow"
		ewarn "3dnowext mmx mmxext sse sse2 ssse3) are properly set."
	fi

	if use ffmpeg-mt && use external-ffmpeg; then
		ewarn "USE flags ffmpeg-mt and external-ffmpeg are not compatible, external-ffmpeg will be used."
	fi
}

src_unpack() {
	if [[ ${PV} = *9999* ]]; then
		git_src_unpack

		if ! use external-ffmpeg; then
			use ffmpeg-mt && x="-mt"|| x=""
			EGIT_REPO_URI="git://git.mplayerhq.hu/libswscale"
			EGIT_PROJECT="libswscale"
			S+="/ffmpeg${x}/libswscale"
			git_fetch
			S="${WORKDIR}/${P}"
		fi

		cd "${WORKDIR}"
	else
		 unpack ${A}
	fi

	if ! use truetype; then
		unpack font-arial-iso-8859-1.tar.bz2 \
			font-arial-iso-8859-2.tar.bz2 \
			font-arial-cp1250.tar.bz2
	fi

	use svga && unpack "svgalib_helper-${SVGV}-mplayer.tar.gz"
}

src_prepare() {
	if [[ ${PV} = *9999* ]]; then
		git_src_prepare
		# Set GIT version manually
		cd "${S}/mplayer"
		echo "GIT-r$(git rev-list HEAD|wc -l)-$(git describe --always)" \
			> VERSION || die "set vesrion failed"
		cd "${S}"

		# remove internal libs and use system:
		sed -e '/^mplayer: /s/libass//' -i Makefile || die "sed failed"
		rm -rf libass mplayer/libfaad2 mplayer/libdvdcss || die
	else
		# Set version #
		echo "${MPLAYER_REVISION}" \
			> mplayer/VERSION || die "set vesrion failed"
	fi

	if use external-ffmpeg; then
		sed -e '/^mplayer: /s/ffmpeg//' -i Makefile || die "sed failed"
	else
			if use ffmpeg-mt;then
				touch ffmpeg-mt-enabled || die "enable-mt failed"
				rm -rf ffmpeg || die
			else
				rm -rf ffmpeg-mt || die
			fi
	fi

	# We want mplayer${namesuf}
	if [[ "${namesuf}" != "" ]]; then
		cd mplayer
		sed -e "/elif linux ; then/a\  _exesuf=\"${namesuf}\"" \
			-i configure || die "sed configure failed"
		sed -e "/ -m 644 DOCS\/man\/en\/mplayer/i\	mv DOCS\/man\/en\/mplayer.1 DOCS\/man\/en\/mplayer${namesuf}.1" \
			-e "/ -m 644 DOCS\/man\/\$(lang)\/mplayer/i\	mv DOCS\/man\/\$(lang)\/mplayer.1 DOCS\/man\/\$(lang)\/mplayer${namesuf}.1" \
			-e "s/er.1/er${namesuf}.1/g" \
			-i Makefile || die "sed Makefile failed"
		sed -e "s/mplayer/mplayer${namesuf}/" \
			-i TOOLS/midentify.sh || die "sed midentify failed"
		cd "${S}"
	fi

	if use svga; then
		echo
		einfo "Enabling vidix non-root mode."
		einfo "(You need a proper svgalib_helper.o module for your kernel"
		einfo "to actually use this)"
		echo

		mv "${WORKDIR}/svgalib_helper" "${S}/libdha"
	fi

	base_src_prepare
}

src_configure() {
	local myconf=""
	local uses i

	# set LINGUAS
	[[ -n $LINGUAS ]] && LINGUAS="${LINGUAS/da/dk}"

	# mplayer ebuild uses "use foo || --disable-foo" to forcibly disable
	# compilation in almost every situation.  The reason for this is
	# because if --enable is used, it will force the build of that option,
	# regardless of whether the dependency is available or not.

	###################
	#Optional features#
	###################
	myconf+="
		--disable-arts
		--disable-kai
		$(use_enable network)
		$(use_enable joystick)
	"
	uses="ass bl enca ftp rtc" # nemesi <- not working with in-tree ebuild
	myconf+=" --disable-nemesi" # nemesi automagic disable
	for i in ${uses}; do
		use ${i} || myconf+=" --disable-${i}"
	done
	use bidi || myconf+=" --disable-fribidi"
	use ipv6 || myconf+=" --disable-inet6"
	use nut || myconf+=" --disable-libnut"
	use rar || myconf+=" --disable-unrarexec"
	use samba || myconf+=" --disable-smb"
	if ! use lirc; then
		myconf+="
			--disable-lirc
			--disable-lircc
			--disable-apple-ir
		"
	fi

	# libcdio support: prefer libcdio over cdparanoia
	# don't check for cddb w/cdio
	if use cdio; then
		myconf+=" --disable-cdparanoia"
	else
		myconf+=" --disable-libcdio"
		use cdparanoia || myconf+=" --disable-cdparanoia"
		use cddb || myconf+=" --disable-cddb"
	fi

	################################
	# DVD read, navigation support #
	################################
	#
	# dvdread - accessing a DVD
	# dvdnav - navigation of menus

	# use external libdvdcss, dvdread and dvdnav
	myconf+=" --disable-dvdread-internal --disable-libdvdcss-internal"

	if use dvd; then
		use dvdnav || myconf+=" --disable-dvdnav"
	else
		myconf+="
			--disable-dvdnav
			--disable-dvdread
		"
	fi

	#############
	# Subtitles #
	#############
	#
	# SRT/ASS/SSA (subtitles) requires freetype support
	# freetype support requires iconv
	# iconv optionally can use unicode

	if ! use ass; then
		if ! use truetype; then
			myconf+=" --disable-freetype"
			if ! use iconv; then
				myconf+="
					--disable-iconv
					--charset=noconv
				"
			fi
		fi
	fi
	use iconv && use unicode && myconf+=" --charset=UTF-8"

	#####################################
	# DVB / Video4Linux / Radio support #
	#####################################
	myconf+=" --disable-tv-bsdbt848"
	# broken upstream, won't work with recent kernels
	myconf+=" --disable-ivtv"
	if { use dvb || use v4l || use v4l2 || use pvr || use radio; }; then
		use dvb || myconf+=" --disable-dvb"
		use pvr || myconf+=" --disable-pvr"
		use v4l	|| myconf+=" --disable-tv-v4l1"
		use v4l2 || myconf+=" --disable-tv-v4l2"
		if use radio && { use dvb || use v4l || use v4l2; }; then
			myconf+="
				--enable-radio
				$(use_enable encode radio-capture)
			"
		else
			myconf+="
				--disable-radio-v4l2
				--disable-radio-bsdbt848
			"
		fi
	else
		myconf+="
			--disable-tv
			--disable-tv-v4l1
			--disable-tv-v4l2
			--disable-radio
			--disable-radio-v4l2
			--disable-radio-bsdbt848
			--disable-dvb
			--disable-v4l2
			--disable-pvr"
	fi

	##########
	# Codecs #
	##########
	myconf+=" --disable-musepack" # Use internal musepack codecs for SV7 and SV8 support
	myconf+=" --disable-faad-internal" # always use system media-libs/faad2
	use dts || myconf+=" --disable-libdca"
	use mp3 || myconf+=" --disable-mp3lame --disable-mp3lib"
	uses="a52 bs2b dv lzo"
	for i in ${uses}; do
		use ${i} || myconf+=" --disable-lib${i}"
	done
	uses="faad gif jpeg live mad mng png pnm speex tga theora xanim"
	for i in ${uses}; do
		use ${i} || myconf+=" --disable-${i}"
	done
	if use vorbis || use tremor; then
		use tremor || myconf+=" --disable-tremor-internal"
		use vorbis || myconf+=" --disable-libvorbis"
	else
		myconf+="
			--disable-tremor-internal
			--disable-tremor
			--disable-libvorbis
		"
	fi
	# Encoding
	uses="faac x264 xvid toolame twolame"
	if use encode; then
		for i in ${uses}; do
			use ${i} || myconf+=" --disable-${i}"
		done
	else
		myconf+=" --disable-mencoder"
		for i in ${uses}; do
			myconf+=" --disable-${i}"
			use ${i} && elog "Useflag \"${i}\" require \"encode\" useflag enabled to work."
		done
	fi

	#################
	# Binary codecs #
	#################
	# bug 213836
	if ! use x86 || ! use win32codecs; then
		use quicktime || myconf+=" --disable-qtx"
	fi

	######################
	# RealPlayer support #
	######################
	# Realplayer support shows up in four places:
	# - libavcodec (internal)
	# - win32codecs
	# - realcodecs (win32codecs libs)
	# - realcodecs (realplayer libs)

	# internal
	use real || myconf+=" --disable-real"

	# Real binary codec support only available on x86, amd64
	if use real; then
		use x86 && myconf+=" --codecsdir=/opt/RealPlayer/codecs"
		use amd64 && myconf+=" --codecsdir=/usr/$(get_libdir)/codecs"
	elif ! use bindist; then
			myconf+=" $(use_enable win32codecs win32dll)"
	fi

	################
	# Video Output #
	################
	uses="directfb md5sum sdl"
	for i in ${uses}; do
		use ${i} || myconf+=" --disable-${i}"
	done
	use aalib || myconf+=" --disable-aa"
	use fbcon || myconf+=" --disable-fbdev"
	use fbcon && use video_cards_s3virge && myconf+=" --enable-s3fb"
	use libcaca || myconf+=" --disable-caca"
	use zoran || myconf+=" --disable-zr"

	if ! use kernel_linux && ! use video_cards_mga; then
		 myconf+=" --disable-mga --disable-xmga"
	fi

	if use video_cards_tdfx; then
		myconf+="
			$(use_enable video_cards_tdfx tdfxvid)
			$(use_enable fbcon tdfxfb)
		"
	else
		myconf+="
			--disable-3dfx
			--disable-tdfxvid
			--disable-tdfxfb
		"
	fi

	################
	# Audio Output #
	################
	uses="alsa esd jack ladspa nas"
	for i in ${uses}; do
		use ${i} || myconf+=" --disable-${i}"
	done
	#use openal && myconf+=" --enable-openal" # build fails
	use pulseaudio || myconf+=" --disable-pulse"
	if ! use radio; then
		use oss || myconf+=" --disable-ossaudio"
	fi

	####################
	# Advanced Options #
	####################
	# Platform specific flags, hardcoded on amd64 (see below)
	if use cpudetection; then
		myconf+=" --enable-runtime-cpudetection"
	fi

	# Turning off CPU optimizations usually will break the build.
	# However, this use flag, if enabled, will allow users to completely
	# specify which ones to use.  If disabled, mplayer will automatically
	# enable all CPU optimizations that the host build supports.
	if use custom-cpuopts; then
		uses="3dnow 3dnowext altivec mmx mmxext shm sse sse2 ssse3"
		for i in ${uses}; do
			myconf+=" $(use_enable ${i})"
		done
	fi

	use debug && myconf+=" --enable-debug=3"

	if use x86; then
		filter-flags -fPIC -fPIE
		append-ldflags -nopie
	fi

	is-flag -O? || append-flags -O2
	if use x86 || use x86-fbsd; then
		use debug || append-flags -fomit-frame-pointer
	fi

	###########################
	# X enabled configuration #
	###########################
	if use X; then
		uses="dxr3 ggi xinerama"
		for i in ${uses}; do
			use ${i} || myconf+=" --disable-${i}"
		done
		use dga || myconf+=" --disable-dga1 --disable-dga2"
		use opengl || myconf+=" --disable-gl"
		use osdmenu && myconf+=" --enable-menu"
		use vdpau || myconf+=" --disable-vdpau"
		use video_cards_vesa || myconf+=" --disable-vesa"
		use vidix || myconf+=" --disable-vidix --disable-vidix-pcidb"
		use xscreensaver || myconf+=" --disable-xss"

		if use xv; then
			if use xvmc; then
				myconf+=" --enable-xvmc --with-xvmclib=XvMCW"
			else
				myconf+=" --disable-xvmc"
			fi
		else
			myconf+="
				--disable-xv
				--disable-xvmc
			"
			use xvmc && elog "Disabling xvmc because it requires \"xv\" useflag enabled."
		fi
	else
		myconf+="
		--disable-dga1
		--disable-dga2
		--disable-dxr3
		--disable-ggi
		--disable-gl
		--disable-vdpau
		--disable-vidix
		--disable-vidix-pcidb
		--disable-xinerama
		--disable-xss
		--disable-xv
		--disable-xvmc
		--disable-x11
		"
		uses="dga dxr3 ggi opengl osdmenu vdpau vidix xinerama xscreensaver xv"
		for i in ${uses}; do
			use ${i} && elog "Useflag \"${i}\" require \"X\" useflag enabled to work."
		done
	fi

	common_options="
		--cc=$(tc-getCC)
		--host-cc=$(tc-getBUILD_CC)
	"
	myconf="
		--prefix=/usr \
		--confdir=/etc/mplayer \
		--datadir=/usr/share/mplayer${namesuf} \
		--libdir=/usr/$(get_libdir) \
		${myconf}"

	echo "${common_options}" > common_options
	echo "${myconf}" > mplayer_options

	if ! use external-ffmpeg; then
		local ffconf="--enable-gpl --enable-version3 --enable-postproc
			--enable-nonfree
			--disable-stripping"

		# enabled by default
		use debug || ffconf+=" --disable-debug"
		use network || ffconf+=" --disable-network"

		use custom-cflags && ffconf+=" --disable-optimizations"
		use cpudetection && ffconf+=" --enable-runtime-cpudetect"

		# ffmpeg encoders
		if use encode; then
			use mp3 && ffconf+=" --enable-libmp3lame"
			for i in faac vorbis theora x264 xvid; do
				use ${i} && ffconf+=" --enable-lib${i}"
			done
		else
			ffconf+=" --disable-encoders"
		fi

		# ffmpeg decoders
		use amr && ffconf+=" --enable-libopencore-amrwb
			--enable-libopencore-amrnb"
		for i in gsm faad dirac schroedinger speex vpx; do
			use ${i} && ffconf+=" --enable-lib${i}"
		done
		use jpeg2k && ffconf+=" --enable-libopenjpeg"

		# CPU features
		for i in mmx ssse3 altivec ; do
			use ${i} ||  ffconf+=" --disable-${i}"
		done
		use mmxext || ffconf+=" --disable-mmx2"
		use 3dnow || ffconf+=" --disable-amd3dnow"
		use 3dnowext || ffconf+=" --disable-amd3dnowext"
		# disable mmx accelerated code if PIC is required
		# as the provided asm decidedly is not PIC.
		if gcc-specs-pie ; then
			ffconf+=" --disable-mmx --disable-mmx2"
		fi

		# Try to get cpu type based on CFLAGS.
		# Bug #172723
		# We need to do this so that features of that CPU will be better used
		# If they contain an unknown CPU it will not hurt since ffmpeg's configure
		# will just ignore it.
		for i in $(get-flag march) $(get-flag mcpu) $(get-flag mtune) ; do
			[ "${i}" = "native" ] && i="host" # bug #273421
			[[ ${i} = *-sse3 ]] && i="${i%-sse3}" # bug 283968
			ffconf+=" --cpu=${i}"
			break
		done

		# cross compile support
		if tc-is-cross-compiler ; then
			ffconf+=" --enable-cross-compile --arch=$(tc-arch-kernel) --cross-prefix=${CHOST}-"
			case ${CHOST} in
				*freebsd*)
					ffconf+=" --target-os=freebsd"
					;;
				mingw32*)
					ffconf+=" --target-os=mingw32"
					;;
				*linux*)
					ffconf+=" --target-os=linux"
					;;
			esac
		fi

		# Misc stuff
		use hardcoded-tables && ffconf+=" --enable-hardcoded-tables"

		echo "${ffconf}" > ffmpeg_options
	fi

	sed -e 's/ --/\n--/g' \
		-i *_options || die "sed *_options failed"
}

src_compile() {
	base_src_compile
	# Build only user-requested docs if they're available.
	if use doc ; then
		cd mplayer
		# select available languages from $LINGUAS
		LINGUAS=${LINGUAS/zh/zh_CN}
		local ALLOWED_LINGUAS="cs de en es fr hu it pl ru zh_CN"
		local BUILT_DOCS=""
		for i in ${LINGUAS} ; do
			hasq ${i} ${ALLOWED_LINGUAS} && BUILT_DOCS+=" ${i}"
		done
		if [[ -z $BUILT_DOCS ]]
		then
			emake -j1 -C DOCS/xml html-chunked || die "Failed to generate html docs"
		else
			for i in ${BUILT_DOCS} ; do
				emake -j1 -C DOCS/xml html-chunked-${i} || die "Failed to generate html docs for ${i}"
			done
		fi
	fi
}

src_install() {
	local i

	emake prefix="${D}/usr" \
		BINDIR="${D}/usr/bin" \
		LIBDIR="${D}/usr/$(get_libdir)" \
		CONFDIR="${D}/etc/mplayer" \
		DATADIR="${D}/usr/share/mplayer${namesuf}" \
		MANDIR="${D}/usr/share/man" \
		INSTALLSTRIP="" \
		install || die "emake install failed"

	S+="/mplayer"
	cd "${S}"
	dodoc AUTHORS Changelog Copyright README etc/codecs.conf || die

	docinto tech/
	dodoc DOCS/tech/{*.txt,mpsub.sub,playtree,TODO,wishlist} || die
	docinto TOOLS/
	dodoc TOOLS/* || die
	if use real; then
		docinto tech/realcodecs/
		dodoc DOCS/tech/realcodecs/* || die
		docinto TOOLS/realcodecs/
		dodoc TOOLS/realcodecs/* || die
	fi
	docinto tech/mirrors/
	dodoc DOCS/tech/mirrors/* || die

	if use doc; then
		docinto html/
		dohtml -r "${S}"/DOCS/HTML/* || die
	fi

	if ! use ass && ! use truetype; then
		dodir /usr/share/mplayer${namesuf}/fonts
		# Do this generic, as the mplayer people like to change the structure
		# of their zips ...
		for i in $(find "${WORKDIR}/" -type d -name 'font-arial-*'); do
			cp -pPR "${i}" "${D}/usr/share/mplayer${namesuf}/fonts"
		done
		# Fix the font symlink ...
		rm -rf "${D}/usr/share/mplayer${namesuf}/font"
		dosym fonts/font-arial-14-iso-8859-1 /usr/share/mplayer${namesuf}/font
	fi

	insinto /etc/mplayer
	newins "${S}/etc/example.conf" mplayer.conf || die
	doins "${S}/etc/input.conf" || die
	if use osdmenu; then
		doins "${S}/etc/menu.conf" || die
	fi

	if use ass || use truetype;	then
		cat >> "${D}/etc/mplayer/mplayer.conf" << _EOF_
fontconfig=1
subfont-osd-scale=4
subfont-text-scale=3
_EOF_
	fi

	# bug 256203
	if use rar; then
		cat >> "${D}/etc/mplayer/mplayer.conf" << _EOF_
unrarexec=/usr/bin/unrar
_EOF_
	fi

	dosym ../../../etc/mplayer/mplayer.conf /usr/share/mplayer${namesuf}/mplayer.conf
	newbin "${S}/TOOLS/midentify.sh" midentify${namesuf} || die

	if [[ "${namesuf}" != "" ]] && use symlink; then
		dosym "mplayer${namesuf}" /usr/bin/mplayer
		dosym "mencoder${namesuf}" /usr/bin/mencoder
		dosym "midentify${namesuf}" /usr/bin/midentify
	fi
}

pkg_preinst() {
	[[ -d ${ROOT}/usr/share/mplayer${namesuf}/Skin/default ]] && \
		rm -rf "${ROOT}/usr/share/mplayer${namesuf}/Skin/default"
}

pkg_postrm() {
	# Cleanup stale symlinks
	[ -L "${ROOT}/usr/share/mplayer${namesuf}/font" -a \
			! -e "${ROOT}/usr/share/mplayer${namesuf}/font" ] && \
		rm -f "${ROOT}/usr/share/mplayer${namesuf}/font"

	[ -L "${ROOT}/usr/share/mplayer${namesuf}/subfont.ttf" -a \
			! -e "${ROOT}/usr/share/mplayer${namesuf}/subfont.ttf" ] && \
		rm -f "${ROOT}/usr/share/mplayer${namesuf}/subfont.ttf"
}