# Copyright 1999-2010 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

EAPI="2"
LANGSLONG="pl_PL ru_RU"

inherit eutils qt4-r2 subversion

ESVN_REPO_URI="http://vacuum-im.googlecode.com/svn/trunk"

DESCRIPTION="Qt4 Crossplatform Jabber client."
HOMEPAGE="http://code.google.com/p/vacuum-im"

LICENSE="GPL-3"
SLOT="0"
KEYWORDS=""
PLUGINS="+adiummessagestyle +annotations +autostatus +avatars +bitsofbinary +bookmarks +captchaforms +chatstates +clientinfo +commands +compress +console +dataforms +datastreamsmanager +emoticons +filestreamsmanager +filetransfer +gateways +inbandstreams +iqauth +jabbersearch +messagearchiver +multiuserchat +privacylists +privatestorage +registration +servicediscovery +sessionnegotiation +socksstreams +vcard +xmppuriqueries"
IUSE="${PLUGINS}"

RDEPEND=">=x11-libs/qt-core-4.5:4[ssl]
	>=x11-libs/qt-gui-4.5:4
	>=dev-libs/openssl-0.9.8k
	adiummessagestyle? ( >=x11-libs/qt-webkit-4.5:4 )"
DEPEND="${RDEPEND}"

v_use_needs() {
	for dep in ${@:2}
	do
		use ${1} && use !${dep} && ewarn "USE=${1} requires ${dep}, ${1} will be disabled."
	done
}

pkg_setup() {
	# from revision 931
	v_use_needs captchaforms dataforms
	v_use_needs commands dataforms
	v_use_needs datastreamsmanager dataforms
	v_use_needs registration dataforms
	v_use_needs sessionnegotiation dataforms
}

src_prepare() {
	subversion_wc_info
	sed -e "s/SVN_REVISION=.*/SVN_REVISION=${ESVN_WC_REVISION}/" \
		-i src/loader/loader.pro || die "sed failed"

	for x in ${PLUGINS//+/}
	do
		if ! use ${x}; then
			rm -rf {resources,src/plugins,translations/*}/${x}{,s}{,.qm}
			sed -e "s/${x}//" \
				-i src/plugins/plugins.pro || die "sed failed"
		fi
	done

	# linguas
	for x in ${LANGSLONG}; do
		if ! use linguas_${x%_*}; then
			rm -rf "translations/${x}/"
			sed -e "/translations\/${x}/d" \
				-i src/translations.inc || die "sed failed"
		fi
	done

	# we want system zlib
	rm -rf src/thirdparty/zlib
}

src_compile() {
	eqmake4 vacuum.pro \
		INSTALL_PREFIX="/usr" \
		INSTALL_APP_DIR="${PN}" \
		INSTALL_LIB_DIR="$(get_libdir)" \
		INSTALL_RES_DIR="share"
	emake || die "emake failed"
}

src_install() {
	emake INSTALL_ROOT="${D}" install || die "emake install failed"
}