The ebuild itself v.0.6.6.1 revision 1

coherence-0.6.6.1-r1.ebuild (text/plain), 1.37 KB, created by PhobosK on 2010-05-28 22:28:48 UTC

# Copyright 1999-2010 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

EAPI=2
inherit eutils distutils

MY_P="Coherence-${PV}"

DESCRIPTION="Coherence is a framework written in Python for DLNA/UPnP components"
HOMEPAGE="https://coherence.beebits.net/"
SRC_URI="http://coherence.beebits.net/download/${MY_P}.tar.gz"

LICENSE="MIT"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE=""

# deps are not exact and need some work
DEPEND="dev-python/louie
	dev-python/twisted
	dev-python/twisted-web
	dev-python/configobj
	dev-python/gst-python
	dev-python/nevow"
RDEPEND="${DEPEND}
	dev-python/axiom
	dev-python/gdata
	dev-python/feedparser
	dev-lang/python[sqlite]
	dev-python/tagpy"

S="${WORKDIR}/${MY_P}"

pkg_setup() {
	enewgroup coherence
	enewuser coherence -1 -1 /dev/null coherence
}

src_install() {
	DOCS="docs/*"
	distutils_src_install

	newinitd "${FILESDIR}"/coherence.initd coherence || die
	newconfd "${FILESDIR}"/coherence.confd coherence || die

	insinto /etc
	newins "${FILESDIR}"/coherence.config coherence.conf || die
	fperms 0750 /etc/coherence.conf
	fowners coherence:coherence /etc/coherence.conf

	diropts -m 0750 -g coherence -o coherence
	keepdir /var/lib/coherence
	keepdir /var/log/coherence
}

pkg_postinst() {
	elog "To configure Coherence edit:"
	elog "/etc/conf.d/coherence"
	elog "and refine the options in:"
	elog "/etc/coherence.conf"
}