cachefilesd-0.10.1.ebuild

cachefilesd-0.10.1.ebuild (text/plain), 1.26 KB, created by Bruno Redondi on 2010-05-15 10:09:18 UTC

# Copyright 1999-2010 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

EAPI=2

inherit eutils

DESCRIPTION="CacheFiles is a caching directory on an already mounted filesystem"
HOMEPAGE="http://people.redhat.com/~dhowells/fscache/"
SRC_URI="http://people.redhat.com/~dhowells/fscache/${P}.tar.bz2"

IUSE="doc selinux"
LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~x86"

src_prepare() {
	# fix Makefile
	sed -e '/CFLAGS/s/-g -O2/${CFLAGS}/' -i Makefile || die
	use selinux || sed -e 's/^secctx/# secctx/' -i cachefilesd.conf || die
}
src_install() {
	emake DESTDIR="${D}"  install || die "install failed"

	dodoc README howto.txt

	newconfd "${FILESDIR}"/cachefilesd.conf cachefilesd
	newinitd "${FILESDIR}"/cachefilesd.init cachefilesd

	keepdir /var/cache/fscache
}

pkg_postinst() {
	[[ -d /var/cache/fscache ]] && return
	elog "Before CacheFiles can be used, a directory for local storage"
	elog "must be created.  The default configuration of /etc/cachefilesd.conf"
	elog "uses /var/cache/fscache.  The filesystem mounted there must support"
	elog "extended attributes (mount -o user_xattr)."
	elog ""
	elog "Once that is taken care of, start the daemon, add -o ...,fsc"
	elog "to the mount options of your network mounts, and let it fly!"
}