new version

libmediainfo-0.7.33.ebuild (text/plain), 1.98 KB, created by Nikoli on 2010-05-14 19:39:35 UTC

# Copyright 1999-2010 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

EAPI="2"

inherit autotools confutils multilib

NICE_NAME="MediaInfo"
DESCRIPTION="The ${NICE_NAME} library supplies technical and tag information about media files"
HOMEPAGE="http://mediainfo.sourceforge.net"
SRC_URI="mirror://sourceforge/mediainfo/source/${PN}/${PV}/${PN}_${PV}.tar.bz2"

S="${WORKDIR}/${NICE_NAME}Lib/Project/GNU/Library"

LICENSE="LGPL-3"
SLOT="0"
KEYWORDS="~amd64 ~ppc ~ppc64 ~x86"
IUSE="curl debug doc libmms static-libs"

RDEPEND="sys-libs/zlib
	>=dev-libs/libzen-0.4.14[static-libs=]
	curl? ( net-misc/curl )
	libmms? ( >=media-libs/libmms-0.4 )"
DEPEND="${RDEPEND}
	dev-util/pkgconfig
	doc? ( app-doc/doxygen )"

src_prepare() {
	# https://bugs.launchpad.net/libmms/+bug/531326
	sed -i -e 's/mmsx/mms/g' "${WORKDIR}/${NICE_NAME}Lib/Source/MediaInfo/Reader/Reader_libmms.cpp"

	eautoreconf
}

src_configure() {
	local myconf="
		--disable-dependency-tracking \
		--enable-shared \
		$(use_enable debug) \
		$(use_with curl libcurl) \
		$(use_with libmms)"
		if use static-libs; then
			myconf+=" --enable-static=yes --enable-staticlibs"
		else
			myconf+=" --enable-static=no --disable-staticlibs"
		fi
	econf ${myconf} || die "econf failed"
}

src_compile() {
	emake || die "emake failed"
	if use doc; then
		cd "${WORKDIR}/${NICE_NAME}Lib/Source/Doc"
		doxygen Doxyfile
	fi
}
src_install() {
	einstall || die "einstall failed"

	insinto "/usr/$(get_abi_LIBDIR)/pkgconfig"
	doins "${PN}.pc"

	insinto "/usr/include/${NICE_NAME}"
	doins "${WORKDIR}/${NICE_NAME}Lib/Source/${NICE_NAME}/"*.h

	for subinc in Archive Audio Duplicate Export Image Multiple Reader Tag Text Video; do
		insinto "/usr/include/${NICE_NAME}/${subinc}"
		doins "${WORKDIR}/${NICE_NAME}Lib/Source/${NICE_NAME}/${subinc}/"*.h
	done

	dodoc "${WORKDIR}/${NICE_NAME}Lib/"*.txt
	if use doc; then
		dohtml "${WORKDIR}/${NICE_NAME}Lib/Source/Doc/Documentation.html"
		dohtml -r "${WORKDIR}/${NICE_NAME}Lib/Doc"
	fi
}