# Copyright 1999-2009 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/sci-geosciences/josm/josm-2.561.ebuild,v 1.1 2009/12/22 20:57:12 hanno Exp $

inherit eutils java-pkg-2 java-ant-2 subversion

DESCRIPTION="Java-based editor for the OpenStreetMap project"
HOMEPAGE="http://josm.openstreetmap.de/"
SRC_URI=""
LICENSE="GPL-2"
SLOT="0"

ESVN_REPO_URI="http://josm.openstreetmap.de/svn/trunk"

KEYWORDS=""

DEPEND=">=virtual/jdk-1.6"
RDEPEND=">=virtual/jre-1.6"

S="${WORKDIR}/${PN}"

IUSE=""

src_unpack() {
	subversion_src_unpack

	local wc_path=$(subversion__get_wc_path "${ESVN_REPO_URI}")
	sed -i "s:value=\".\":value=\"${wc_path}\":" build.xml || die "sed build.xml failed"
}

src_compile() {
	JAVA_ANT_ENCODING=UTF-8
	eant dist
}

src_install() {
	java-pkg_newjar "dist/${PN}-custom.jar" || die "java-pkg_newjar failed"
	java-pkg_dolauncher "${PN}" --jar "${PN}.jar" || die "java-pkg_dolauncher failed"

	newicon images/logo.png josm.png || die "newicon failed"
	make_desktop_entry "${PN}" "Java OpenStreetMap Editor" josm "Application"
}