1.6.003

egroupware-1.6.003.ebuild (text/plain), 1.99 KB, created by Maciej Mrozowski on 2010-04-28 17:03:42 UTC

# Copyright 1999-2010 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

EAPI="2"

inherit eutils webapp depend.php

MY_PN=eGroupware
MY_PV="${PV/_/.}"

DESCRIPTION="Web-based GroupWare suite"
HOMEPAGE="http://www.egroupware.org/"
SRC_URI="mirror://sourceforge/${PN}/${MY_PN}-${MY_PV}.tar.bz2
	mirror://sourceforge/${PN}/${MY_PN}-egw-pear-${MY_PV}.tar.bz2
	mydms? ( mirror://sourceforge/${PN}/${MY_PN}-mydms-${MY_PV}.tar.bz2 )
	icalsrv? ( mirror://sourceforge/${PN}/${MY_PN}-icalsrv-${MY_PV}.tar.bz2 )
	gallery? ( mirror://sourceforge/${PN}/${MY_PN}-gallery-${MY_PV}.tar.bz2 )"

LICENSE="GPL-2"
KEYWORDS="~alpha ~amd64 ~hppa ~ppc ~sparc ~x86"
IUSE="jpgraph ldap mssql mysql postgres mydms icalsrv gallery"

RDEPEND="
	jpgraph? ( dev-php5/jpgraph )
	dev-lang/php[ctype,imap,ldap?,mssql?,pdo,postgres?,session,unicode]
	|| (
		dev-lang/php[gd]
		dev-lang/php[gd-external]
	)
	dev-php/PEAR-Auth_SASL
	dev-php/PEAR-PEAR
	dev-php/PEAR-XML_Feed_Parser
	virtual/cron
"

need_httpd_cgi
need_php_httpd

S=${WORKDIR}/${PN}

src_prepare() {
	esvn_clean

	if use jpgraph; then
		einfo "Fixing jpgraph location"
		sed -i "s|EGW_SERVER_ROOT . '/../jpgraph/src/jpgraph.php'|'/usr/share/php${PHP_VERSION}/jpgraph/jpgraph.php'|" \
			projectmanager/inc/class.projectmanager_ganttchart.inc.php || die
		sed -i "s|EGW_SERVER_ROOT . '/../jpgraph/src/jpgraph_gantt.php'|'/usr/share/php${PHP_VERSION}/jpgraph/jpgraph_gantt.php'|" \
			projectmanager/inc/class.projectmanager_ganttchart.inc.php || die
	fi
}

src_install() {
	webapp_src_preinst

	insinto "${MY_HTDOCSDIR}"
	doins -r .

	webapp_serverowned "${MY_HTDOCSDIR}/phpgwapi/images"

	webapp_postinst_txt en "${FILESDIR}/postinstall-en-1.2.txt"
	webapp_src_install
}

pkg_postinst() {
	if use ldap; then
		elog "If you are using LDAP contacts/addressbook, please read the upgrade instructions at"
		elog "http://www.egroupware.org/index.php?page_name=wiki&wikipage=ManualSetupUpdate"
		elog "before running the egroupware setup"
	fi
	webapp_pkg_postinst
}