parrot-2.3.0.ebuild

parrot-2.3.0.ebuild (text/plain), 2.26 KB, created by Alexandre Rostovtsev (RETIRED) on 2010-04-24 06:49:42 UTC

# Copyright 1999-2010 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-lang/parrot/parrot-2.1.1.ebuild,v 1.1 2010/02/28 20:42:07 lu_zero Exp $

EAPI=3

inherit eutils multilib

DESCRIPTION="Parrot is a virtual machine designed to efficiently compile and execute bytecode for dynamic languages"
HOMEPAGE="http://www.parrot.org/"
SRC_URI="ftp://ftp.parrot.org/pub/parrot/releases/supported/${PV}/${P}.tar.bz2"

LICENSE="Artistic-2"
SLOT="0"
KEYWORDS="~amd64 ~ppc ~ppc64 ~sparc ~x86"
IUSE="opengl nls doc examples gdbm gmp ssl +unicode pcre"

RDEPEND="sys-libs/readline
		 opengl? ( virtual/glut )
		 nls? ( sys-devel/gettext )
		 unicode? ( >=dev-libs/icu-2.6 )
		 gdbm? ( >=sys-libs/gdbm-1.8.3-r1 )
		 gmp? ( >=dev-libs/gmp-4.1.4 )
		 ssl? ( dev-libs/openssl )
		 pcre? ( dev-libs/libpcre )"

DEPEND="dev-lang/perl[doc?]
		${RDEPEND}"

src_configure() {
	myconf="--disable-rpath"
	use unicode || myconf="$myconf --without-icu"
	use ssl || myconf="$myconf --without-crypto"
	use gdbm || myconf="$myconf --without-gdbm"
	use nls || myconf="$myconf --without-gettext"
	use gmp || myconf="$myconf --without-gmp"
	use opengl || myconf="$myconf --without-opengl"
	use pcre || myconf="$myconf --without-pcre"

	perl Configure.pl --ccflags="${CFLAGS}" \
					  --linkflags="${LDFLAGS}" \
					  --prefix="${EROOT}"/usr \
					  --libdir="${EROOT}"/usr/$(get_libdir) \
					  --sysconfdir="${EROOT}"/etc \
					  --sharedstatedir="${EROOT}"/var/lib/parrot \
					  --pkgconfigdir=pkgconfig \
					  $myconf
}

src_compile() {
	export LD_LIBRARY_PATH=${LD_LIBRARY_PATH:+$LD_LIBRARY_PATH:}"${S}"/blib/lib
	# occasionally dies in parallel make
	emake -j1 || die
	use doc && make html
}

src_test() {
	emake -j1 test
}

src_install() {
	emake -j1 install-dev DESTDIR="${ED}" DOC_DIR="${EROOT}/usr/share/doc/${P}" || die
	dodoc CREDITS DEPRECATED.pod DONORS.pod NEWS PBC_COMPAT PLATFORMS RESPONSIBLE_PARTIES TODO
	if use examples; then
		insinto "${EROOT}/usr/share/doc/${PF}/examples"
		doins -r examples/*
	fi
	if use doc; then
		insinto "${EROOT}/usr/share/doc/${PF}/editor"
		doins -r editor
		cd docs/html
		dohtml -r developer.html DONORS.pod.html index.html ops.html parrotbug.html pdds.html \
					pmc.html tools.html docs src tools
		
	fi
}