enhanced ebuild

fwknop-1.9.12.ebuild (text/plain), 1.88 KB, created by René 'Necoro' Neumann on 2010-04-01 17:03:07 UTC

# Copyright 1999-2010 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

inherit perl-app

IUSE=""

DESCRIPTION="Single Packet Authorization and Port Knocking"
SRC_URI="http://www.cipherdyne.org/fwknop/download/${PN}-nodeps-${PV}.tar.gz"
HOMEPAGE="http://www.cipherdyne.org/fwknop"

SLOT="0"
LICENSE="GPL-2"
KEYWORDS="~x86"

RDEPEND="virtual/logger
	virtual/mailx
	dev-perl/Class-MethodMaker
	dev-perl/GnuPG-Interface
	dev-perl/Unix-Syslog
	dev-perl/crypt-cbc
	dev-perl/Crypt-Rijndael
	dev-perl/Net-Pcap
	dev-perl/TermReadKey
	dev-perl/Net-RawIP
	dev-perl/Net-IPv4Addr
	dev-perl/IPTables-Parse
	dev-perl/IPTables-ChainMgr
	virtual/perl-Digest-SHA
	virtual/perl-net-ping
	net-firewall/iptables
	net-misc/whois"

src_install() {
	doman *.8

	keepdir /var/log/fwknop /var/run/fwknop

	insinto /usr
	dosbin fwknop fwknop_serv fwknopd knopmd knoptm knopwatchd

	fix_conf

	insinto /etc/fwknop
	doins *.conf
	fperms 600 /etc/fwknop/access.conf

	newinitd init-scripts/fwknop-init.gentoo fwknop

	dodoc CREDITS Change* README README.* VERSION
}

pkg_postinst() {
	echo
	elog "Please be sure to edit /etc/fwknop/fwknop.conf to reflect your system's"
	elog "configuration or it may not work correctly or start up. Specifically, check"
	elog "the validity of the HOSTNAME setting and EMAIL_ADDRESSES"
	echo
	elog "You must edit /etc/fwknop/access.conf for fwknop to work correctly."
}

fix_conf() {
	cp fwknop.conf fwknop.conf.orig

	# Ditch the _CHANGEME_ for hostname, substituting in our real hostname
	sed -i "s:HOSTNAME\(.\+\)\_CHANGEME\_;:HOSTNAME\1$(hostname --fqdn);:" fwknop.conf || die "fix_conf failed"

	# Fix up paths
	sed -i "s:/sbin/syslogd:/usr/sbin/syslogd:g" fwknop.conf || die "fix_conf failed"
	sed -i "s:/sbin/syslog-ng:/usr/sbin/syslog-ng:g" fwknop.conf || die "fix_conf failed"
	sed -i "s:/usr/bin/whois_psad:/usr/bin/whois:g" fwknop.conf || die "fix_conf failed"
}