mail-filter/postfwd-1.17.ebuild

postfwd-1.17.ebuild (text/plain), 2.28 KB, created by Matthias Dahl on 2010-03-31 18:02:27 UTC

# Copyright 1999-2010 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

inherit eutils

DESCRIPTION="Versatile Postfix policy server with a flexible ruleset based configuration"
HOMEPAGE="http://www.postfwd.org/"
SRC_URI="http://www.postfwd.org/${P}.tar.gz"

LICENSE="BSD"
SLOT="0"
KEYWORDS="~amd64"
IUSE="tools"

DEPEND=""
RDEPEND=">=dev-lang/perl-5.8.8-r8
	virtual/perl-Sys-Syslog
	dev-perl/Net-DNS
	dev-perl/net-server
"

pkg_setup() {
	enewgroup postfwd
	enewuser postfwd -1 -1 -1 postfwd
}

src_install () {
	# programs and tools
	dosbin "${S}"/sbin/${PN} || die "failed to install ${PN} w/ dosbin"

	# man pages and documentation
	doman "${S}"/man/man8/${PN}.8 || die "doman failed"
	dodoc "${S}"/doc/{CHANGELOG,postfwd.txt} || die "dodoc failed"

	# example configuration(s)
	insinto /usr/share/doc/${PF}/examples
	newins "${S}"/etc/${PN}.cf.sample ${PN}.cf.dist || die "newins failed"
	newins "${FILESDIR}"/${PN}.example.cf ${PN}.cf.realworld || die "newins failed"

	# tools
	if use tools; then
		newdoc "${S}"/tools/README.TXT README.tools
		dodocins /usr/share/doc/${PF}/tools
		dodoc "${S}"/tools
	fi

	# init script and respective configuration file
	newinitd "${FILESDIR}"/${PN}.init ${PN} || die "newinitd failed"
	newconfd "${FILESDIR}"/${PN}.conf ${PN} || die "newconfd failed"
}

pkg_postinst() {
	einfo
	einfo "${PN} has no default configuration for safety reasons. Every"
	einfo "mail system is different, so you should craft a set of rules"
	einfo "that is suitable for your environment and save it to:"
	einfo "   /etc/postfix/postfwd.cf"
	einfo "You can find example configurations in:"
	einfo "   /usr/share/doc/${PN}/examples"
	einfo
	einfo "If you want ${PN} to start on system boot, you have to add it your"
	einfo "default run level:"
	einfo "   # rc-update add postfwd default"
	einfo "Also remember to edit /etc/conf.d/${PN} to your liking."

	if use tools; then
		einfo
		einfo "You can find additional tools for testing ${PN} in:"
		einfo "   /usr/share/doc/${PN}/tools"
	fi

	ewarn
	ewarn "Please read the documentation carefully and properly test new"
	ewarn "rulesets before putting them into production use. Otherwise you"
	ewarn "risk accidental mail loss or worse."
	ewarn
	ewarn "Visit http://www.postfwd.org/ for more information."
	ewarn
}