new gigi ebuild, based on the new cmake build-system

gigi-9999.ebuild (text/plain), 1.90 KB, created by M. B. on 2010-03-27 15:21:50 UTC

# Copyright 1999-2005 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

EAPI="2"

inherit cmake-utils subversion

DESCRIPTION="GiGi is an OpenGL interface library"
HOMEPAGE="http://gigi.sourceforge.net"
ESVN_REPO_URI="https://gigi.svn.sourceforge.net/svnroot/gigi/trunk"
ESVN_PROJECT="gigi"

LICENSE="LGPL-2.1"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="debug devil doc ogre ois sdl static threads"

RDEPEND="
    devil? ( >=media-libs/devil-1.6.1 )
    !devil? ( media-libs/jpeg
        media-libs/tiff
        media-libs/libpng )
    ogre? ( >=dev-games/ogre-1.4.7 )
    ois? ( dev-games/ois )
    sdl? ( >=media-libs/libsdl-1.2 )
    >=dev-libs/boost-1.34
    media-libs/freetype
    media-libs/mesa"

DEPEND="${RDEPEND}
    doc? ( app-doc/doxygen )
    dev-util/pkgconfig"

CMAKE_USE_DIR="${S}/GG"
CMAKE_BUILD_DIR="${S}/GG"

pkg_setup() {
    if use !ogre && use ois ; then
        die "Please enable the ogre use-flag when enabling the ois use-flag."
    fi
}

src_unpack() {
    subversion_src_unpack
}

src_prepare() {
    # Install the documentation into '/usr/share/doc' instead of '/usr/doc'
    if use doc ; then
        epatch "${FILESDIR}/9999-doc-rectification.patch" \
            || die "Could not sed with new doc location."
    fi
}

src_configure() {
    mycmakeargs=(
        $(cmake-utils_use_build debug)
        $(cmake-utils_use devil)
        $(cmake-utils_use_build doc DOCUMENTATION)
        $(cmake-utils_use_build ogre OGRE_DRIVER)
        $(cmake-utils_use_build ois OGRE_OIS_PLUGIN)
        $(cmake-utils_use_build sdl SDL_DRIVER)
        $(cmake-utils_use_build static)
        $(cmake-utils_use_build !static SHARED)
        $(cmake-utils_use_build threads MULTI_THREADED)
        $(cmake-utils_use_build !threads SINGLE_THREADED)
    )
    
    cmake-utils_src_configure
}

src_compile() {
    cmake-utils_src_compile
}

src_install() {
    cmake-utils_src_install
}