media-sound/denemo-0.8.14.ebuild

denemo-0.8.14.ebuild (text/plain), 1.44 KB, created by Jared B. on 2010-03-27 12:32:38 UTC

# Copyright 1999-2009 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

EAPI=2
inherit autotools font

FONT_S="${S}/fonts"
FONTDIR="/usr/share/fonts/truetype/denemo"
FONT_SUFFIX="ttf"

DESCRIPTION="GTK+ graphical music notation editor."
HOMEPAGE="http://denemo.sourceforge.net"
SRC_URI="http://download.savannah.gnu.org/releases/${PN}/${P}.tar.gz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~ppc sparc x86"
IUSE="doc +fluidsynth jack +lilypond nls"

RDEPEND=">=x11-libs/gtk+-2:2
	>=dev-libs/libxml2-2.3.10
	gnome-base/librsvg
	>=media-libs/aubio-0.3.2
	>=media-libs/portaudio-19_pre
	>=dev-scheme/guile-1.8
	media-libs/alsa-lib
	>=x11-libs/gtksourceview-2.0
	>=sci-libs/fftw-3.1.2
	>=media-libs/libsamplerate-0.1.2
	fluidsynth? ( media-sound/fluidsynth )
	jack? ( >=media-sound/jack-audio-connection-kit-0.102 )
	lilypond? ( media-sound/lilypond )"
DEPEND="${RDEPEND}
	|| ( dev-util/yacc sys-devel/bison )
	sys-devel/flex
	dev-util/pkgconfig
	nls? ( sys-devel/gettext )"

src_prepare() {
	# Wrong directory, icons is for theme sets
	sed -e 's:icons:pixmaps:g' -i src/view.c \
		-i pixmaps/Makefile.am || die "sed failed"
	eautoreconf
}

src_configure() {
	econf \
		--disable-dependency-tracking \
		$(use_enable doc) \
		$(use_enable fluidsynth) \
		$(use_enable nls) \
		$(use_enable jack)
}

src_install() {
	emake DESTDIR="${D}" install || die "emake install failed"
	dodoc AUTHORS ChangeLog NEWS README*
	font_src_install
}