# Copyright 1999-2010 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

inherit multilib toolchain-funcs

DESCRIPTION="Small dynamic tiling window manager for X11"
HOMEPAGE="http://www.scrotwm.org/"
SRC_URI="http://www.scrotwm.org/snapshot/${P}.tgz"

LICENSE="ISC"
SLOT="0"
KEYWORDS="~amd64"
IUSE=""

RDEPEND="x11-libs/libX11
	x11-libs/libXrandr
	x11-libs/libXt
	x11-misc/dmenu"
DEPEND="${RDEPEND}
	x11-proto/xproto"

S=${WORKDIR}/${PF}/linux

src_unpack() {
	unpack ${A}
	cd "${S}"

	# Do not compile with an enhanced symbol table by default, and add the ELF
	# SONAME tag to the library.
	sed -i -e "/^CFLAGS/s/-ggdb//" -e						\
	    "/\$(LVERS)/s/\$(CC)/& \$(LDFLAGS),-soname,\$@/"	\
		Makefile || die "sed cflags failed"
}

src_compile() {
	emake CC="$(tc-getCC)" LIBDIR="/usr/$(get_libdir)"|| die "emake failed"
}

src_install() {
	dobin scrotwm || die "dobin failed"
	dolib.so libswmhack.so* || die "dolib.so failed"
	doman ../scrotwm.1 || die "doman failed"
	dodoc ../*.{conf,sh} || die "dodoc failed"
}