# Copyright 1999-2010 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

EAPI="2"

inherit java-pkg-2 java-ant-2

MY_P="${P/_alpha/.a}"
MY_PV="${PV/_alpha/.a}"

# New release without updated pv so place the
# correct ver here
MY_V="1.1.3"
MY_MV="$(get_version_component_range 1-2)"

DESCRIPTION="A Java based remote management console used for Managing Fedora Administration / Directory Server"
HOMEPAGE="http://directory.fedoraproject.org/"
SRC_URI="http://port389.org/sources/${MY_P}.tar.bz2
	http://ftp.disconnected-by-peer.at/389-ds/1.1.x/${MY_P}.tar.bz2"

LICENSE="LGPL-2.1"
SLOT="1.1"
KEYWORDS="~amd64 ~x86"
IUSE=""

#S=${WORKDIR}/fedora-idm-console-${PV}

COMMON_DEP="=dev-java/jss-4*
	>=dev-java/ldapsdk-4.0
	>=dev-java/idm-console-framework-1.1
	!app-admin/fedora-idm-console
	!app-admin/389-idm-console"
RDEPEND=">=virtual/jre-1.6
	${COMMON_DEP}"
DEPEND=">=virtual/jdk-1.6
	${COMMON_DEP}"

S="${WORKDIR}/${PN}-${MY_PV}"

src_prepare() {
	java-pkg_jarfrom ldapsdk-4.1 ldapjdk.jar
	java-pkg_jarfrom jss-3.4 xpclass.jar jss4.jar
	java-pkg_jarfrom idm-console-framework-1.1
}

src_compile() {
	eant -Dbuilt.dir="${S}"/build \
	    -Dldapjdk.local.location="${S}" \
	    -Djss.local.location="${S}" \
	    -Dconsole.local.location="${S}"
}

src_install() {
	java-pkg_newjar "${S}"/build/389-console-${MY_V}_en.jar 389-console_en.jar
	java-pkg_dolauncher ${PN} --main com.netscape.management.client.console.Console \
				--pwd "/usr/share/dirsrv/html/java/" \
				--pkg_args "-Djava.util.prefs.systemRoot=\"\$HOME/.${PN}\" -Djava.util.prefs.userRoot=\"\$HOME/.${PN}\""

	doicon "${FILESDIR}"/port389.png
	make_desktop_entry ${PN} "Port389 Management Console" port389.png Network
}