# Copyright 1999-2009 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

EAPI="2"
inherit java-pkg-2

DESCRIPTION="an open source programming language and environment for people who want to program images, animation, and sound"
HOMEPAGE="http://processing.org/"
SRC_URI="http://processing.org/download/${P}.tgz"

LICENSE="GPL-2 LGPL-2.1"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE=""

DEPEND=">=virtual/jdk-1.5"
RDEPEND="${DEPEND}
	dev-java/ant-core
	dev-java/antlr
	dev-java/eclipse-ecj
	dev-java/jna
	amd64? (
		app-emulation/emul-linux-x86-java
		app-emulation/emul-linux-x86-xlibs
	)"
#	www-apps/browser-config

QA_EXECSTACK="usr/share/processing/libraries/serial/library/librxtxSerial.so"

src_prepare() {
	rm -rf java || die

	rm lib/{ant,ant-launcher,antlr,ecj,jna}.jar || die
	java-pkg_jar-from --into lib/ ant-core || die
	java-pkg_jar-from --into lib/ antlr || die
	java-pkg_jar-from --into lib/ "eclipse-$(eselect ecj show)" || die
	java-pkg_jar-from --into lib/ jna || die

	# www-apps/browser-config
	#sed -i -e '/^browser.linux/s:mozilla:runbrowser:' lib/preferences.txt || die
	sed -i -e '/^browser.linux/s:mozilla:firefox:' lib/preferences.txt || die

}

src_install() {
	java-pkg_addcp '$(java-config --tools)' || die
	java-pkg_dojar lib/*.jar || die
	rm lib/*.jar || die

	insinto "${JAVA_PKG_JARDEST}" || die
	doins -r lib/* || die

	libopts -m0755
	for lib in $(find libraries -name '*.so') ; do
		java-pkg_sointo "${JAVA_PKG_SHAREPATH}/$(dirname ${lib})" || die
		java-pkg_doso "${lib}" || die
		rm "${lib}" || die
	done

	insinto "${JAVA_PKG_SHAREPATH}"
	doins -r libraries examples revisions.txt tools || die

	#java-pkg_doexamples examples/* || die
	#dosym /usr/share/doc/${PF}/examples "${JAVA_PKG_SHAREPATH}/examples" || die

	java-pkg_dohtml -r reference/* || die
	dosym /usr/share/doc/${PF}/html "${JAVA_PKG_SHAREPATH}/reference" || die

	java-pkg_dolauncher ${PN} --main processing.app.Base --pwd "${JAVA_PKG_SHAREPATH}" || die
}