Updated ebuild with "progs" support

leptonica-1.64.ebuild (text/plain), 1.46 KB, created by Rodrigo Severo on 2010-03-17 20:57:07 UTC

# Copyright 1999-2010 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

EAPI=2

inherit autotools multilib

MY_P="leptonlib-${PV}"
DESCRIPTION="An open source C library for image processing and analysis"
HOMEPAGE="http://www.leptonica.com/"
SRC_URI="http://www.leptonica.com/source/${MY_P}.tar.gz"

LICENSE="Apache-2.0"
SLOT="0"
KEYWORDS="~amd64"
IUSE="progs"

DEPEND="media-libs/jpeg
	media-libs/giflib
	media-libs/tiff"
RDEPEND="${DEPEND}"

S=${WORKDIR}/${MY_P}

DOCS=( README version-notes )

src_prepare() {
	# build shared library
	epatch "${FILESDIR}"/${PN}-build-shared.diff

	if use progs ; then
		epatch "${FILESDIR}"/${PN}-prog-makefile-remove_Werror.diff
	fi

	eautoreconf

	# unhtmlize docs (they're just one big <pre/>s)
	local docf
	for _docf in ${DOCS[@]}; do
		awk '/<\/pre>/{s--} {if (s) print $0} /<pre>/{s++}' \
			${_docf}.html > ${_docf} || die 'awk failed.'
	done
}

src_compile() {
	emake || die 'main emake failed.'
	
	if use progs ; then
		cd ${S}/src
		emake || die 'src emake failed.'

		cd ${S}/prog
		emake || die 'prog emake failed.'

		cd ${S}
	fi
}

src_install() {
	emake install DESTDIR="${D}" || die 'main emake install failed.'

	if use progs ; then
		cd ${S}/prog
		emake install DESTDIR="${D}" || die 'prog emake install failed.'
		cd ${S}
	fi

	dodoc ${DOCS[@]} || die 'dodoc failed.'

	# remove .la file, it was needed only to build shared lib
	rm "${D}"/usr/$(get_libdir)/liblept.la || die 'rm failed.'
}